You have 4 levels of temperature and 3 growth chambers, so you clearly did not assign the same temperature level twice to the same growth chamber; if you did to some extent, then the models I propose below are not consistent with your design.
If we assume that there is no systematic chamber effect on the mean response and that there is no systematic temporal effect on the mean response, then we can think of your design as having 8 growth chambers, randomly assigned to 4 temperatures. (This obviously is not what you did, but might be a good-enough model if the assumptions are valid.) The 3 blocks within each chamber are not true replications, rather they are subsamples because they are not independent realizations of a particular temperature level. You can fit a model with the full set of 144 observations:
proc glimmix data=wue
plots=(studentpanel boxplot(fixed student));
class run block temp var;
model inswue = temp var temp*var / ddfm=kr2 ;
random run(temp)
block*run(temp)
var*run(temp);
lsmeans temp var / diff adjust=tukey lines cl;
lsmeans temp*var / plot=meanplot(sliceby=var join cl) slice=(temp var);
run;
or you can compute the means over the 3 blocks within each chamber for each variety and fit a model with 48 observations:
proc sort data=wue out=wue_srt;
by run temp var;
proc means data=wue_srt noprint;
by run temp var;
var inswue;
output out=wue_means mean= ;
run;
proc glimmix data=wue_means
plots=(studentpanel boxplot(fixed student));
class run temp var;
model inswue = temp var temp*var / ddfm=kr2 ;
random run(temp);
lsmeans temp var / diff adjust=tukey lines cl;
lsmeans temp*var / plot=meanplot(sliceby=var join cl) slice=(temp var);
run;
This second model is a two-way factorial in a split-plot design; the first model is a form of split-plot with subsamples. Because you have the same number of blocks in each chamber, the test results are the same for both models.
I think these models are, more or less, valid and certainly more correct than your original model, if I correctly understand your design. There is no evidence of interaction, so (unfortunately) your original question is now moot.
I hope this helps.
