Since the generated dummy variables will be treated as completely separate variables, the selection method could choose only a subset of them, so that only a portion of the original variable is selected. But this is a bit like reducing the number of categories in the original categorical variable in such as way as to include only the important contrasts with the reference level. That might be a desirable result when using a selection method to select a parsimonious model.
Another thought on an alternative to the SELECTION=SCORE method in PROC LOGISTIC: While it is not the same method and cannot be implemented in a single procedure step, a somewhat similar thing could be done by sequentially using the START= option in the MODEL statement and the MAXEFFECTS= option in the SELECTION statement in either PROC HPLOGISTIC or PROC HPGENSELECT. This method can be used with your CLASS variables. The following illustrates it. Note that MAXEFFECTS=1 allows only the intercept, so values greater than 1 select candidate predictors. The following generates simulated data with candidate continuous variables x1-x5 and categorical variables c1 and c2. The known true model involves only the x1, x2, and c1 variables. Selection starts with MAXEFFECTS=2 to find the best model of size 1 (1 predictor). In the next step, the variable selected is specified in the START= option and MAXEFFECTS= is increased to 3 to find the best model of size 3 (2 predictors). And so on to find the best models of increasing size. This uses significance level for selection, but there are options in the SELECTION statement that lets you select other criteria. Note that x: refers to all variables with names beginning with "x". Similarly with c: .
data Simdata;
drop i j;
array x{5} x1-x5;
do i=1 to 1000;
do j=1 to 5;
x{j} = ranuni(1); /* Continuous predictors */
end;
c1 = int(1.5+ranuni(1)*7); /* Classification predictors */
c2 = 1 + mod(i,3);
yTrue = 2 + 5*x2 - 17*x1*x2 + 6*(c1=2) + 5*(c1=5);
y = yTrue + 2*rannor(1);
p=logistic(yTrue);
b=rantbl(1,1-p,p)-1;
output Simdata;
end;
run;
proc hplogistic;
class c:;
model b=x: c: ;
selection method=stepwise(maxeffects=2 sle=.3 sls=.5);
run;
proc hplogistic;
class c:;
model b=x: c: / start=(x1);
selection method=stepwise(maxeffects=3 sle=.3 sls=.5);
run;
proc hplogistic;
class c:;
model b=x: c: / start=(x1 c1);
selection method=stepwise(maxeffects=4 sle=.3 sls=.5);
run;
proc hplogistic;
class c:;
model b=x: c: / start=(x1 c1 x2);
selection method=stepwise(maxeffects=5 sle=.3 sls=.5);
run;
proc hplogistic;
class c:;
model b=x: c: / start=(x1 c1 x2 c2);
selection method=stepwise(maxeffects=6 sle=.3 sls=.5);
run;
