Following the comments by lvm, I looked at the ERRORMODEL statement. It appears that PROC MODEL code that is consistent with PROC NLMIXED code would be something like:
proc model data=SASUSER.PREDLINREGPREDICTIONSFILTER_FOR_;
PARMS b0 b1;
y = b0 + b1*EAD_gesamt;
G = exp(-exp(-y));
neg_ll = -(NEQ_UNBES_ABGEZ*log(G)+(1-NEQ_UNBES_ABGEZ)*log(1-G));
ERRORMODEL binom ~ General(neg_ll);
run;
Now, how you can integrate estimation of an autocorrelation in the above code, I don't know and don't have time to investigate. However, I can suggest use of the GLIMMIX procedure as an alternative approach which can estimate both likelihood and quasi-likelihood models. For the quasi-likelihood model, you could incorporate some autocorrelation structure in the estimation model.
GLIMMIX code to estimate the likelihood model specified above would be
proc glimmix data=SASUSER.PREDLINREGPREDICTIONSFILTER_FOR_;
model NEQ_UNBES_ABGEZ = EAD_gesamt / dist=binary link=cloglog;
run;
We can modify the above GLIMMIX code to estimate a model with an AR(1) covariance structure for the residuals by adding a random statement as shown below:
proc glimmix data=SASUSER.PREDLINREGPREDICTIONSFILTER_FOR_;
model NEQ_UNBES_ABGEZ = EAD_gesamt / dist=binary link=cloglog;
random _residual_ / subject=intercept type=ar(1);
run;
Note that with the addition of the "random _residual_" statement, a quasi-likelihood estimation procedure is invoked.
Rather than an AR(1) covariance structure, you might want to estimate a model with a first-order autoregressive moving-average covariance structure. That can be done by replacing the TYPE=AR(1) specification with TYPE=ARMA(1,1). There are many other covariance structures which can be estimated with the GLIMMIX procedure. Most of them will probably not be of interest to you.
I would note that the above code assumes that all observations belong to a single time series. If you have multiple time series (for instance, you have collected time series values for multiple companies or multiple countries), then you must use a different SUBJECT= specification. Again, a better description of the statistical problem would enable a more authoritative response.