Bootstrap MAIC weighted data with surveyselect, and use samples in proc lifereg.

[amoynahan]

I want to create 5000 bootstrap samples from patient level data stratified by treatment and with a MAIC weight.

My question are: 1) How to sample using proc surveyselect using a weight, 2) when you use one of the samples in proc lifereg do you use the original weight, or assume that the weight in now incorporated into the sample though the weighting procedure

I use the method pps_wr in proc surveyselect, and using the weight with the size option.

data patients;
  length treatment $10;
  set os;
  keep usubjid treatment weight;
run;

proc sort data=patients;
  by treatment usubjid;
run;

proc sql;
  create table sampsize as
  select treatment, count(*) as _nsize_
    from patients
    group by treatment;
quit;

proc surveyselect data=patients(keep=usubjid treatment weight)
  out=patients_samples(keep=sample usubjid treatment weight)
  sampsize=sampsize
  method=pps_wr
  reps=5000(repname=sample)
  seed=8675309
  outhits noprint;
  strata treatment;
  size weight;
run;

data os_samples;
  merge os (in=a keep=usubjid time event weight)
  patient_samples(in=b);
  by usubjid;
  if a and b;
run;

proc sort data=os_samples;
  by sample usubjid;
run;

/*** For this last 

/* Note: I'm actually using flexsurv in R at this point */

proc lifereg data=os_samples;

  by sample;

  class treatment;
  model time*event(0) =treatment / distribution = weibull;

  weight weight; /* Should this statement be included ? */
run;

So again, should this weight statement be included in samples that were created with the weight, or should it be dropped at this point?

[Rick_SAS]

It looks like you are using the WEIGHT variable to select observations. If so, you do not need it in PROC LIFEREG.

In general, when you bootstrap, you are trying to discover how a point estimate in an analysis varies in random samples. You start with an analysis. The BY statement runs the same analysis on a collection of similar random data (the resamples). So, with the exception of the BY statement, your PROC LIFEREG statements should look exactly the same as in the original analysis. So if your original PROC LIFEREG statement does not have a WEIGHT statement, neither should your bootstrap analysis.

[amoynahan]

Thank you for the reply. It makes sense. Once you use the weight statement to do the sample, the weights are baked into the composition of the new sample.