How to include multiple variables in PROC SGPLOT or SGPANEL

[pdrsn13]

I am comparing median laboratory values and mortality.  I have 10 different labs on about 400 patients.  I have created a box and whisker plot for each lab individually and mortality - see simple example code below.  I would like them to all be included in one panel such as with sgpanel but since they are separate variables, I haven't been able to figure it out.  They would each require their own Y axis since they have different scales.

I would also love help with labeling mortality (outcome, 0 = deceased, 1 = survived) on the x-axis.

proc sgplot data=eb;
title 'AST overall value by survival';
vbox AST / category=outcome;
run;

[acordes]

data test;
array temp (*) _NUMERIC_ val1-val10;

do client=1 to 400;
do j=1 to dim(temp);
temp(j)=ceil(rand('integer',1,10) + rand("normal", mod(client, 5), rand('bernoulli', rand('integer',1,10)/10))) ;
end;
client_id=cats("id_", client);
outcome= rand('bernoulli', mod(client, 3)/2);
output;
end;

drop client j;

run;

proc format;
value outy
0='deceased'
1='survived'
;
run;


ods graphics on;
proc sgplot data=test;
format outcome outy.;
title 'AST overall value by survival';
vbox val1 / category=outcome;
run;

proc transpose data=test out=long(rename=(col1=value));
by client_id outcome notsorted;
var val1-val10;
run;

proc sgpanel data=long;
panelby _name_;
format outcome outy.;
vbox value / category=outcome;
run;