ods powerpoint issues - slide margin, table padding and odslist background color

[working_bot]

First time post here. Please let me know how to make it better.

I try formatting a bullet list in a text box and a table on ods powerpoint.

My desired format (see below screenshots):

• The whole text box background color should be yellow. The first line "Comment Box" should not have a bullet.
• The text box and table below should start at the most left of the slide, leaving no margin.
• The table's Cell Margins should be all 0s. (In PowerPoint it is in Layout - Cell Margins)

Below is my code:

  *HTML output;
  ods html;

  *PPT output;
  options nocenter orientation=landscape topmargin=0in bottommargin=0in 
        leftmargin=0in rightmargin=0in papersize=(13.33in 7.5in);
  ods powerpoint file=".\__temp.pptx" nogtitle nogfootnote;

  *Title and comment box;
  ods layout gridded x=0pct y=0pct;
  ods region;
  proc odstext; p "Title" / style=[color=green TEXTALIGN=L FONTWEIGHT=BOLD FONTSIZE=24pt]; run;
  proc odslist;
/*  cellstyle 1 as {background=lightyellow};*/
  item / style={liststyletype="none" TEXTALIGN=L fontsize=12pt background=yellow};
    p "Comment Box";
    p "Comment Box2";
    list / style={liststyletype="disc" TEXTALIGN=L fontsize=12pt FONTWEIGHT=BOLD background=yellow};
     item "Bullet1";
     item "Bullet2";
    end;
  end;
  run;
  ods layout end;

  *A table;
  ods layout gridded;
  ods region;
  proc print data=sashelp.class  noobs label WIDTH=MINIMUM
  style(header)={cellpadding=0pt /*paddingleft=0pt paddingright=0pt*/ paddingbottom=0pt paddingtop=0pt foreground=black background=grey fontsize=11pt just=c}
  style(column)={cellpadding=0pt paddingleft=0pt paddingright=0pt paddingbottom=0pt paddingtop=0pt fontsize=11pt just=c}
  ;
  run;  
  ods layout end;

  *Close and Output;
  ods powerpoint close;

Below is the original PowerPoint output screenshot.

Below is what I would like to have.

Thank you in advance!

[Ksharp]

You could use PROC REPORT to replace PROC ODSLIST.

options nocenter orientation=landscape topmargin=0in bottommargin=0in 
        leftmargin=0in rightmargin=0in papersize=(13.33in 7.5in);
  ods powerpoint file="c:\temp\temp.pptx" nogtitle nogfootnote;
title;

data x;
input x $80.;
cards;
Comment Box
Comment Box2
(*ESC*){style [foreground=yellow].......}●    Bullet1
(*ESC*){style [foreground=yellow].......}●    Bullet2
;

  *Title and comment box;
  ods layout gridded x=0pct y=0pct;
  ods region;
  proc odstext; p "Title" / style=[color=green TEXTALIGN=L FONTWEIGHT=BOLD FONTSIZE=24pt]; run;


proc report data=x nowd noheader 
style(column)={rules=none frame=void background=yellow bordercolor=yellow fontsize=12pt cellpadding=0 cellspacing=0};
run;


  ods layout end;

  *A table;
  ods layout gridded;
  ods region;
  proc print data=sashelp.class(obs=10)  noobs label WIDTH=MINIMUM
  style(header)={cellpadding=0pt /*paddingleft=0pt paddingright=0pt*/ paddingbottom=0pt paddingtop=0pt foreground=black background=grey fontsize=11pt just=c}
  style(column)={cellpadding=0pt paddingleft=0pt paddingright=0pt paddingbottom=0pt paddingtop=0pt fontsize=11pt just=c}
  ;
  run;  
  ods layout end;

  *Close and Output;
  ods powerpoint close;