how to remove leading and traling space inside brackets

[raja777pharma]

Hi ,

How to remove the leading and traling spacce inside brackets.

My data is below.

data have;

input_var $200;

cards;

( 12.5)

(   1.5)

(111.9)

(  2.8)

( 20.0)

;

run;

Thank you,

Rajasekhar.

[Shmuel]

new_var = compress(var);

[raja777pharma]

Hi ,

Thank you for response.

I am wrongly post the data , i need to remove the space in side the bracket only.

data have;

infile datalines truncover;

input_var $200;

234  (  23.5)

0

12   (   34)

30 ( 12.5)

34  ( 0.5 )

;

run;

[Reeza]

Show the code used to create that field instead and we can show you how to modify it.

[ballardw]

---

@raja777pharma wrote:

Hi ,

Thank you for response.

I am wrongly post the data , i need to remove the space in side the bracket only.

data have;

infile datalines truncover;

input_var $200;

234  (  23.5)

0

12   (   34)

30 ( 12.5)

34  ( 0.5 )

;

run;

---

That data step still does not run. Incorrect statement: input _var  NOT input_var

The Informat should end a dot: $200.

[Tom]

If the strings only have the one parenthetical value then I would just rebuild it.

data have;
  input var $char80.;
cards;
234  ( 23.5)
  0
 12  (   34)
 30  ( 12.5)
 34  ( 0.5 )
;


data want;
  set have;
  new_var=var;
  if index(var,'(') then 
    new_var = substrn(var,1,index(var,'('))
            ||compress(substrn(var,index(var,'(')+1))
  ;
  put (var new_var) (:$quote./) /;
run;

Results:

"234  ( 23.5)"
"234  (23.5)"

"  0"
"  0"

" 12  (   34)"
" 12  (34)"

" 30  ( 12.5)"
" 30  (12.5)"

" 34  ( 0.5 )"
" 34  (0.5)"

PS: Your British is showing.  The characters used to include parentheticals are called parentheses.  Brackets look like this: [ ].

[ballardw]

You should show what you expect the result to be so can have a chance of seeing if our suggestions do as desired.

Also, please run your data step and make sure it creates the desired data. Yours has issues as posted.

This is my attempt.

data have;
infile datalines truncover;
input _var $200. ;
_var = compress(_var,' ');
cards;
( 12.5)
(   1.5)
(111.9)
(  2.8)
( 20.0)
;

The Truncover is because you are requesting reading so many characters with the $200. informat (incorrectly specified in your code) that SAS will attempt to read from following lines and only gets a couple of records, AFTER fixing the informat and incorrect INPUT statement.

Compress function removes characters.

[Ksharp · Accepted solution]

data have;
  input var $char80.;
cards;
234  ( 23.5)
  0
 12  (   34)
 30  ( 12.5)
 34  ( 0.5 )
;


data want;
  set have;
  new_var=prxchange('s/\(\s*([\d\.,]+)?\s*\)/(\1)/',-1,var);
run;