how to do a one-hot encoding process by using proc transpose?

[duanzongran]

dear all:

I know how to do one-hot encoding with data step.Is it possible to do it by using proc transpose?

data basic_info;
input name $ sex $;
datalines;
A Female
B Male
C Female
D Female
E Male
;
run;

Any sugesstion is welcome!

[Ksharp]

data basic_info;
input name $ sex $;
dummy=1;
datalines;
A Female
B Male
C Female
D Female
E Male
;
run;
proc glmselect data=basic_info outdesign(addinputvars)=want(drop=dummy);
class sex;
model dummy=sex/selection=none noint;
run;

[Kurt_Bremser]

You need to have a value which you can transpose.

data basic_info;
input name $ sex $;
val = 1;
datalines;
A Female
B Male
C Female
D Female
E Male
;

proc transpose data=basic_info out=want1 (drop=_name_);
by name;
var val;
id sex;
run;

data want;
merge
  basic_info
  want1
;
by name;
run;

Conversion of missing to 0 can be done manually in the MERGE step, or with PROC STDIZE.

[Reeza]

And just a note, though you may already be aware, that if using certain procedures this is unnecessary as param=ref will do the encoding automatically.