Using 'if' and 'not' in an array

[Angmar]

Hello,

I have another array question.

I'm trying to identify records that have an observation of 'X30' in them, but only if other observations in the variable suite (diagnosis codes 2-25) do not contain 'T67'. I tried a few variations of the code below, but I'm not well-versed in using arrays. The code below gives me ERROR 390-185: Expecting an relational or arithmetic operator.

Thank you

DATA LIB.D0521;
SET LIB.D0521;
ARRAY DX (25) DIAG_CODE_1-DIAG_CODE_25 ;
DO i = 1 TO 25;
IF DX(i) =: 'X30' AND DX(i) NOT 'T67' THEN X30_ONLY_DIAGS=1;
END;
RUN;

[ballardw]

If the log shows an underline under the value 'T67' that is because NOT as an operation expects something SAS will treat as a logical comparison. That would mean an expression like  not(somevar = 25) or a numerical variable since SAS will treat values of 0 and missing as False and most other numeric values as true.

So instead of

DX(i) NOT 'T67'

You may have wanted

DX[i] ne 'T67'

Maybe. 

If you want to search all members of the array you might want

if dx(i) =:'X30' and index( catx(',', of dx(*)),'T67') = 0 then X_30_only_diags=1;

The Index function returns the position of the second argument, the T67, in the first argument, the Catx function result, or 0 if not present.

The catx will return a comma delimited list of the values of the DX array with leading/trailing spaces removed.

[Angmar]

Thank you, but neither worked.

They both returned the same number of records (around 2900 out of a possible 3300), but they still contained observations of T67.

Thank you again, and I appreciate your suggestion.

[SASKiwi]

I suspect you are wanting to know if T67 is in ANY of the array variables, in which case you could count up the number of occurrences. If ALL of your 25 codes start with X30 (X30_Count = 25), they can't possibly include T67 as well.

DATA LIB.D0521;
SET LIB.D0521;
ARRAY DX (25) DIAG_CODE_1-DIAG_CODE_25 ;
X30_Count = 0;
T67_Count = 0;
DO i = 1 TO 25;
if DX(i) = 'T67' then T67_Count + 1;
IF DX(i) =: 'X30' THEN X30_Count + 1;
END;
RUN;

[Tom · Accepted solution]

You have syntax error and a logic error.

Syntax:  The unary NOT operator wants a boolean value, not a string, as its argument.

Logic:  You need to test all of the codes to see if none of them are T67.

DATA LIB.D0521;
  SET LIB.D0521;
  ARRAY DX DIAG_CODE_1-DIAG_CODE_25 ;
  anyX30 =0;
  anyT67 =0;
  DO i = 1 TO 25;
    IF DX(i) =: 'X30' then anyx30=1;
    IF DX(i) =: 'T67' THEN anyt67=1;
  END;
  if anyx30 and not anyt67 ;
RUN;

[Angmar]

I see - thank you!

[andreas_lds]

Do yourself a favour and don't overwrite datasets during code development, to avoid having to restore the dataset to its original state.

Could you please post some obs of the dataset your are processing? That may allow us to spot issues with the code more easily.