Understanding the infile + input combination

[ArtemisFowl]

Hello,

When reading a .txt file into SAS, I have trouble figuring out exactly why something works and something else doesn't.

For instance, I have a text file with this content:

1---+----10---+----20---+---

01/05/1989    Rick      11

12/25/1987    Sue       13

01/05/1991    Sally     9

If I run the code

data work.family;

   infile 'C:\test.txt';

   input @1 birth_date mmddyy10.

         @15 first_name $5.

         @25 age 3.;

run;

then I get a dataset with only one row, namely

10597 Rick .

So the date and name turns out alright, but the age doesn't.

If I include the "truncover" option, then the output turns out alright, but I have no idea why.

Kind regards,

Rasmus.

[Tom · Accepted solution]

You told it to try to read past the end of the line.  The first row has only 26 characters and your input statement tried to read 27 so it flowed over to the next line to get more characters. So the first pass through the data step "eats" the first two lines and results in the observation you see.  On the second pass you again tried to read past the end of the line so it tried to get more again, but this time there were no more lines so the data step stopped without writing the observation for Sally because you read past the end of the input file.

TRUNCOVER is the best way to fix this.

You can also add : prefix to your informats.  This will tell SAS to stop looking for characters when it hits a space or an end of line.

data work.family;

   infile 'C:\test.txt';

   input @1 birth_date : mmddyy10.

         @15 first_name : $5.

         @25 age : 3.

   ;

run;

[ArtemisFowl]

Thanks, Tom.

That makes a lot of sense.