Not opening ZIP or xlsx files from unknown sources. Program text is best copy/paste into a code box opend on the forum with either the </> or "running man" icons.
You have to create a new variable. Once a variable exists in a SAS data set the variable type is fixed.
So if you did not use something like
newvar = input(charactervar, anydtdte.);
then that is likely part of your issue.
If you have a lot of files of similar format to read you are almost always better off writing a data step so they are all processed the same. Since Proc Import will make different "guesses" for each file imported you can spend way more time "fixing" things that could have been prevented by reading properly the first time.
Yes, it appears you do not have a simple file format to read. But SAS can examine a line of text in the file and you can find key values and pick appropriate alternate code to process the line.
data example;
infile datalines dlm=',' ;
input @;
if _infile_ =: 'contact_date' or missing (_infile_) then do;
input;
delete;
end;
ampmpos = max(index(_infile_,'AM'),index(_infile_,'PM'));
if 0< ampmpos < 24 then do;
/*likely found AM PM as part of date*/
contact_date = input(substr(_infile_,1,ampmpos+1),anydtdtm32.);
input;
end;
format contact_date dateampm.;
drop ampmpos;
datalines;
contact_date
1/1/2012 12:00:00 AM
12/23/2004 12:00:00 AM
contact_date
03/04/2005 12:00:00 AM
contact_date
12/13/2004 12:00:00 AM
;
The INPUT @ holds the current input line until told to advance with another Input statement.
_INFILE is an automatic variable that holds the line of the input file. So you can test it for key values and use appropriate INPUT to read the value in the desired form (often called parsing a line of text).
I suspect your file is more complex but without an actual TXT example, copy for your file with a text editor and paste into a code box opened on the forum with the </> icon, not going to do much more. The code box is critical in this case because the message window will reformat the text otherwise.
You don't discuss the "BA" that appears. If that is supposed to be some sort of identifier then you could read it and retain the value to keep on records until another identifier appears. Or if this is always on the first/second/what have you line of the file that can be read first with an input and then conditionally execute other input statements based on whether that is set (not missing).
Click image to register for webinar
