@_maldini_ wrote:
The syntax you provided will give me the mean across the class variable, which is helpful. But, I'm trying to determine how to calculate a mean for each time point that can be output as its own variable. For example, baseline_mean, timepoint_1_meanscore, timepoint_2_meanscore, which would be added to the existing dataset as new variables.
If I conduct a paired t-test, for example, and I need the mean difference across 2 timepoints (e.g., timepoint_2_meanscore minus baseline_mean), I need to use the following syntax:
PROC TTEST DATA=dataset-name ALPHA=.05;
PAIRED V1*V2;
RUN;
I'm assuming V1 and V2 above are means that I need to calculate from each timepoint. Am I wrong about that?
Thanks for your help.
You are at a point where you really need to provide an example of what you think the data set would look like.
Proc means data=yourdataset nway noprint;
class redcap_event_name;
var Vas <other variable names>;
output out=work.summary mean= /autoname;
run;
For example will create a mean for each level of the even_name of the variables and have the word "mean" as a suffix.
But I'm not sure how you expect to run much of a t-test on these summary values.
I think that you may want to transpose the data so that you have one each variable and use "timepoint" as the variable.
data example;
infile datalines dlm=',' dsd;
input record_id redcap_event_name :$15. age vas pain interference adherence ;
datalines;
1,Baseline,44,7,7,6,
1,Follow-up #1,,6,5,5,3
1,Follow-up #2,,4,3,3,4
2,Baseline,55,7,5,5,
2,Follow-up #1,,4,2,4,3
2,Follow-up #2,,3,1,3,5
3,Baseline,37,5,4,5,
3,Follow-up #1,,4,3,3,6
3,Follow-up #2,,0,1,2,4
4,Baseline,56,3,4,3,
4,Follow-up #1,,3,4,2,3
4,Follow-up #2,,3,2,1,6
5,Baseline,64,7,5,6,
5,Follow-up #1,,5,4,4,3
5,Follow-up #2,,3,2,2,2
;
proc transpose data=example
out=trans1;
by record_id;
id redcap_event_name;
var vas pain interference adherence ;
run;
proc sort data=trans1;
by _name_;
run;
proc ttest data=trans1;
by _name_;
paired baseline*Follow_up__1;
run;
This uses the power of "by group" processing to the same thing based on the value of a variable in the data set, in this case the type of measure. The sort and transpose gets the values for type of measurement and the names of the "timepoints" as the variable to analyze.
With the reshaped data we test the type of measure by each value of the original variable name. So with one set of code we test all the baseline * follow_up__1 pairs.
Warning: If your variable names don't look like mine you may want to play with the system option validvarname=V7 to avoid having to write variable names like "follow up #1"n. Or make the text for the follow up values more acceptable as variable names such as "FollowUp1" and "FollowUp2".
The data step turns you posted data into a data step, you shouldn't need to do that. In the future, please open a text box on the forum by clicking on the </> and paste the csv text into it.
Click image to register for webinar
