Here's a sample program that does "recursive" regressions using sashelp.stocks. Each regression is identified by STOCK, BEG_DATE, and END_DATE, where BEG_DATE in your case is a constant. The "trick" is not to constantly re-read observations to perform recursive regressions, but rather to pass through the data once, creating recursive SSCP's, which can then be read into PROC REG, with a BY STOCK BEG_DATE END_DATE set of by groups. Of course, you'll probably want to tell the proc reg to output datasets of estimates rather than printing to the listing file as I have below:
proc sort data=sashelp.stocks out=have;
by stock date;
format date date9.;
run;
%let earliest_begdate=01jan1990;
%let earliest_enddate=01jan1992;
data recursive_sscp (type=SSCP drop=_I _J _nv_plus_intercept _nobs rename=(date=end_date));
set have (keep=stock date close high low open);
by stock;
where date >= "&earliest_begdate"d;
retain beg_date ;
format beg_date date9.;
array vars{*} Intercept Open High Low Close;
array vnames{5} $32 _temporary_ ('Intercept','Open','High','Low','Close');
retain _nv_plus_intercept 5;
array sscp{5,5} _temporary_;
intercept=1;
_nobs+1;
if first.stock then do;
beg_date=date;
_nobs=1;
call missing(of sscp{*});
end;
do _I=1 to _nv_plus_intercept;
sscp{_I,_I}+vars{_I}**2;
if _I < _nv_plus_intercept then do _J=_I+1 to _nv_plus_intercept ;
sscp{_I,_J}+vars{_I}*vars{_J};
sscp{_J,_I}=sscp{_I,_J};
end;
end;
if date>="&earliest_enddate"d;
_type_='SSCP';
do _I=1 to _nv_plus_intercept;
_name_=vnames{_I};
do _J=1 to _nv_plus_intercept;
vars{_j}=sscp{_I,_J};
end;
output;
end;
_type_='N';
_name_=' ';
do _J=1 to _nv_plus_intercept;
vars{_J}=_nobs;
end;
output;
run;
proc reg data=recursive_sscp plots=none;
by stock beg_date end_date;
model close=open low high;
quit;
Note that not only is there a variable named _TYPE_ in data set recursive_sscp, but also the dataset itself has TYPE=SSCP (run a proc contents on it and you'll see). The longer your recursive windows become, the more likely you'll see performance improvements.
[edited addition]
Also I have set to macrovars to tell SAS when the beginning of each window is to be, and also the range of the shortest acceptable window.
