Read a Variable Value into a Macro Variable

[CurtisSmithDCAA]

I need to read the value of a variable into a macro variable and then in the same data step use the macro variable as the upper limit in a do loop. My code is as follows:

data work.test;
set in.test_data;
call symput('mqty',trim(Order_Quantity));
put "Quantity = &mqty.";
do i=1 to "&mqty.";
output;
end;
run;

But, the symput only processes the last row in the data set, so it uses that value in each iteration of the do loop.

Any suggestions?

[Kurt_Bremser]

Why not do

data work.test;
set in.test_data;
do i=1 to order_quantity;
  output;
end;
run;

?

[CJac73]

What @KirkBresmer said. You can still do the macro var, but it is the same value as order_quantity

[ScottBass]

I need to read the value of a variable into a macro variable and then in the same data step use the macro variable as the upper limit in a do loop.

This will never work.  Read the macro doc to understand the difference between compile time vs. run time execution.

In your example:

data work.test;
set in.test_data;
call symput('mqty',trim(Order_Quantity));
put "Quantity = &mqty.";
do i=1 to "&mqty.";
output;
end;
run;

&mqty (lines 4 & 5) is evaluated before the data step starts execution.

Also, I recommend call symputx over call symput.

[Tom]

There is no need in your example since you already have the value in the dataset.

If you did need to read the value of a macro variable dynamically then use SYMGET() or SYMGETN() function.

Try this program.

%let x1=5;
%let x2=3;
data test;
do row=1 to 2;
  do obs=1 to symgetn(cats('x',row));
    output;
  end;
end;
run;

[Astounding]

do i=1 to symgetn('mqty');

[ScottBass]

@Tom and @Astounding are very smart SAS professionals, and I bow to their expertise.  They've both helped me more times than I can count (although that presumes I can count very high).

However, in this instance, I'll point out that I feel their examples are illustrative only, just so you understand the concept of symget and symgetn.  I don't think using symget is the approach you should be using in your example.  (Actually, Tom made it clear that it was just an example).

If you find yourself loading a data step variable into a macro variable (call symput), then wanting to reference that macro variable in the same data step (symget), 99.99% of the time you should just use the data step variable instead.  Moving data to/from the macro symbol table is much slower than using data in the PDV/data step.

In summary, use @Kurt_Bremser 's approach.

[Kurt_Bremser]

And if you need to keep values across observations, the data step provides multiple tools for this:

• lag() functions
• retained variables
• temporary arrays
• hash objects

which will all perform better than invoking the macro processor repeatedly while the step is running.