Proc format to create a format from a dataset

[NJGIRL]

Hi all!

Long time programmer here, however, I am stumped!

Why the heck isn't the format retaining the zeros when I have indicated the format type as 'C'?  Here is the code :

data subject(keep=siteid start label fmtname usubjid new_id);

length new_id $12;

set db.en end=end;

new_id = substr(usubjid,8,3) || substr(usubjid,4,3) ;

start = new_id;

label = usubjid;

retain fmtname "SubjectFmt" type "C";

output;

if end then do;

hlo = 'O' ;

label = 'ERROR ;

end;

run;

proc format cntlin = subject cntlout = cntlout; run;

proc format library=work; select SubjectFmt; run;

attached are exampled of the dataset and the resulting format.

Thank you!

NJGirl

[ChrisNZ]

Is usubjid a string?

[NJGIRL]

Hi ChrisNZ,

It is a character.

[andreas_lds]

Please don't hide information in office-files, many contributors won't open such files. Post data as data step using datalines, and attach screenshots using "insert photos" (the small camera icon). And don't forget to post the log as text using "insert code" so that formatting is maintained.

[FreelanceReinh]

---

@NJGIRL wrote:

Why the heck isn't the format retaining the zeros when I have indicated the format type as 'C'?  Here is the code :

data subject(keep=siteid start label fmtname usubjid new_id);

...

Hi @NJGIRL,

Add type to the KEEP= list.

Also add the missing quotation mark in

---

label = 'ERROR ;

[Tom · Accepted solution]

Names of character formats start with $.

Why do you assign a value to TYPE but then drop the variable?

Why do you assign a vlaue to HLO but then drop the variable?
Why do never output the HLO observation?

data subject;
  length fmtname $32 type $1 hlo $3 start new_id $12;
  set db.en end=end;
  new_id = substr(usubjid,8,3) || substr(usubjid,4,3) ;
  start = new_id;
  label = usubjid;
  retain fmtname '$SubjectFmt' type 'C';
  output;
  if end then do;
    hlo = 'O' ;
    label = 'ERROR';
    output;
  end;
  *keep fmtname type start label hlo ;
run;

proc format cntlin = subject cntlout = cntlout; run;

proc format library=work fmtlib; select $SubjectFmt; run;

[NJGIRL]

THANKS SO MUCH TOM. YOU ARE VERY GOOD AT QUICKLY REVIEWING CODE AND SEEING THE OBVIOUS:()

(I guess the answer to your questions would be this: I was staring at it for way too long and couldn't see beyond the weeds. got way too wrapped up it. This happens to me when I stare at code for hours and hours every day!! PHEW.:) 🙂