This should get you started.
filename widget "<path to your file>\SOP_widget.txt";
data work.rawwidget;
length number $ 25. title $ 500.
policy purpose applicability responsibility
materials procedure references cross_references keywords
original_date_issued date_reviewed date_revised reviewed_by
$ 32767.
tempstr $ 32767
;
retain number title
policy purpose applicability responsibility
materials procedure references cross_references keywords
original_date_issued date_reviewed date_revised reviewed_by
tempstr
;
infile widget lrecl=32767 dsd eof=Lastline;
start: input @;
if _infile_ =: 'NUMBER:' then do;
number = strip(tranwrd(_infile_,'NUMBER:',''));
end;
if _infile_ =: 'TITLE:' then do;
title = strip(tranwrd(_infile_,'TITLE:',''));
end;
if _infile_ =: 'POLICY:' then do;
policy = strip(tranwrd(_infile_,'POLICY:',''));
end;
if _infile_ =: 'PURPOSE:' then do;
purpose = strip(tranwrd(_infile_,'POLICY:',''));
end;
if _infile_ =: 'APPLICABILITY:' then do;
applicability = strip(tranwrd(_infile_,'APPLICABILITY:',''));
end;
if _infile_ =: 'RESPONSIBILITY:' then do;
responsibility = strip(tranwrd(_infile_,'RESPONSIBILITY:',''));
end;
if _infile_ =: 'Materials' then do ;
input;
do until (scan(_infile_,1) = 'Procedure' );
/* at this point we have a section that needs to be read from multiple lines
so we read the current line and place into an accumulator variable
*/
input ;
if scan(_infile_,1) = 'Procedure' then leave;
materials = catx('; ',materials,_infile_);
end;
end;
/* advance to next line in file*/
input;
/* continue reading next line into same record*/
goto start;
/* write to output set when last line is read*/
lastline: Output;
run;
This has some assumptions such as the examples that only occupied one line will consider to do so. I assumed that your title may not be as long and set 500 characters, increase as needed. If you are sure other variables will be shorter you can set them to a desired maximum length.
There are some moderately complicated timing issues to get only one record output with each variable filled. The RETAIN statement is likely not needed but I can foresee the possibility of needing some OUTPUT statements to debug some behavior.
I only did ONE of the multiple line reader sections leaving that as an example.
There are Labels, START and LASTLINE. These are references for program flow. The LASTLINE is intended to only write when the end of the file is encountered and uses the EOF infile option to tell SAS when to execute that statement. The GOTO goes back to reading to advance through the file. If you remove, or comment that line out you will get an output record for each line in the file.
_INFILE_ is an automatic SAS variable that holds the current input buffer (up to 32K characters) line so you can search it do things conditionally, even edit.
The =: is a "starts with" so if the line starts with your keyword the program executes the desired bit. This is case sensitive and if your files are consistent in spelling, capitalization and placement should not be a problem. May have to modify code if not.
There is some slightly tricky bits in the Multiple line reading for Materials and if you have a Materials section NOT followed by Procedure there is going to be a problem. The solution would be looking for any of the following key words.
There is a not really common instruction LEAVE in the loop that tells the program to leave the loop before adding the word Procedure to the end of the Materials list. Likely there are a couple of other ways but I'm not getting paid to optimize code, this is volunteer labor.
I placed a '; ' between sections of the materials because data with line feeds as part of the values can cause numerous problems. The CATX strips blanks so the code doesn't need to do that. You may or may not need a line separator in the other multi-line bits like p
At the end of the loop that reads materials you should be on the first line where Procedure occurs.
Click image to register for webinar
