@biglerc wrote:
I am afraid hashes are way over my head. 😞
The hash object comes with a learning curve, but it's a worthwhile addition to the toolkit of every experienced DATA step programmer. There are great textbooks about it available.
Here's an implementation of the plan (in its simplest form) I outlined in my previous post:
data want(drop=k);
call streaminit(27182818);
if _n_=1 then do;
if 0 then set mentor;
dcl hash h(dataset: 'mentor');
h.definekey('mentor_id');
h.definedata(all: 'y');
h.definedone();
dcl hiter hi('h');
end;
set mentee;
array s[999] $2 _temporary_; /* increase dim. of S or define it as a hash obj. if >999 mentors */
do while(hi.next()=0);
if .<input(mentee_level,32.)<input(mentor_level,32.) & mentee_subfunc ne mentor_subfunc
then do;
k=sum(k,1);
s[k]=mentor_id;
end;
end;
if k then do; /* i.e., if at least one suitable mentor has been found */
h.find(key: s[rand('integer',k)]);
h.remove();
call missing(of s[*]);
end;
else do;
put 'WAR' 'NING: No suitable mentor found for ' mentee_id=;
call missing(of mentor_:);
end;
run;
It works for your sample data (thanks for providing the datasets!).
The basic structure of this DATA step is:
data want;
set mentee;
... code to randomly select suitable mentor ...
run;
So, dataset WANT is actually a copy of dataset MENTEE with all variables from the MENTOR dataset added: mentor_id, mentor_subfunc and mentor_level contain the data of a randomly selected mentor satisfying the criteria for the respective mentee. They are empty if no suitable mentor was found (e.g., because all suitable mentors were assigned to other mentees in earlier observations).
The code before the set mentee statement
- sets an arbitrary positive random seed (needed to get reproducible results from the RAND function used later)
- adds the variables of the MENTOR dataset to the program data vector (technical requirement for using the hash object)
- declares and creates a hash object H containing all values of dataset MENTOR, assuming that mentor_id is a unique key in that dataset
- declares and creates a hash iterator object HI which will be used to traverse the hash object H.
The first few elements of temporary array S will be populated with the IDs of those mentors who satisfy the criteria for the current mentee (read from the MENTEE dataset by the SET statement) and who haven't been assigned to a mentee in an earlier observation -- if any. Type and length of the array ($2) elements match the characteristics of variable mentor_id (a character variable of length 2). As defined above, it can accommodate up to 999 mentor IDs, but the dimension can be increased if needed.
You can think of the DO-WHILE loop (using the NEXT method of the hash iterator object HI) as a kind of SET statement applied to the "copy" of the MENTOR dataset stored in hash object H (or what's left of it after removing mentors assigned to other mentees), as it reads one observation per iteration. I hope the IF condition reflects your selection criteria appropriately:
- I assumed that "lower level" means a smaller, non-missing numeric value of the mentee_level variable compared to the mentor_level variable (e.g. 8 < 101). Unfortunately, these variables are character variables so that I had to use the INPUT function to extract the numeric values.
- For the second criterion ("not the same subfunction") I used a simple string comparison. Modifications would be needed if values of mentee_subfunc or mentor_subfunc weren't consistent regarding case, spelling, etc.
Once the hash object containing the mentor data has been read from beginning to end, the IDs of suitable mentor "candidates" for the current mentee are found in s[1], s[2], ..., s[k]. Each of the k candidates has the same probability of being selected by the RAND function. The FIND method of the hash object retrieves the values of mentor_id, mentor_subfunc and mentor_level of the selected mentor, who is then removed from the hash object to prevent a duplicate selection. The list of candidates is cleared by the CALL MISSING routine.
In the unfortunate case that no suitable mentor has been found (which doesn't happen with your sample data) a warning is written to the log and the mentor_... variables will be blank in dataset WANT for such an observation.
At the end of each iteration of the DATA step the usual implied OUTPUT statement writes the mentee and assigned mentor data to dataset WANT.
