Macro list issue - Proc SQL seperate by ' ' ?

[ybz12003]

Hi all:

I created a macro list by Proc SQL.   However, I found there are space between the ID and could not be recognized in Where statement.  For example, ID is 'DCT00025', 'DEY00056', 'DWR00047', etc.  After the macro, it became ''DCT00025  ', 'DEY00056  ', 'DWR00047 '.   Please advice how to solve this problem.  Thanks.

proc sql noprint;
	select ID into : Unmatchlist separated by " ',' " from Unmatch;
quit;
 
%put &Unmatchlist;

data Want;
	set Test (keep = ID SITE DATE);
	where ID in ('&Unmatchlist');
run;

Then I got my macro Unmatch list like this:

1037 %put &Unmatchlist;

DCT00025  ', '  DEY00056  ', '  DWR00047

Which makes them unrecognized in the where statement.

[Kurt_Bremser]

Do it in one SQL:

proc sql;
create table want as
select id, site, date
from test
where id in (select id from unmatch);
quit;

[ybz12003]

Hi KurtBremser:

I think the Q is answered more closed by Novinosrin, although your code is definitely more directly and simple.  

[Peter_C]

Select ID format= $quote100. Into unmatchList separated by ', '
From unmatch

The $quote format applies the trimming

[Peter_C]

I should add the usage of the macro variable needs no quotes:
Where ID in( &unmatchList)

[novinosrin · Accepted solution]

data unmatch;
input id $10.;
cards;
DCT00025
DEY00056
DWR00047
;
proc sql noprint;
	select quote(strip(ID)) into : Unmatchlist  separated by  ','   from Unmatch;
quit;
 
%put &Unmatchlist;

data Want;
	set Test (keep = ID SITE DATE);
	where ID in (&Unmatchlist);
run;

[Peter_C]

Storing leading blanks seem unnatural to me, in the SAS environment.
Hence I never think of using STRIP() function.
And I should test whether the $quote format performs STRIP or TRIM in my SQL code above