Macro: Validation of libname

[SasStatistics]

I am writing a macro of the form: 

%macro MacroCompareTables(base, compare, formatshort); 
	%if &formatshort NE 0 or &formatshort NE 1 %then %do; 
		%put ERROR: formathsort should be 1 (for short version) or 0 (for long version).;
	%end; 

	/* Here I would like to do validation on the tables base and compare provided. For example 
	if no libname assigned then it should be from work. If the tables not found in work, 
	I would like to tell the user that no such table available in the work. 
	Any suggestion on good things to do here?*/ 

	%if &formatshort = 1 %then %do; 
		proc compare briefsummary warning  base=&basem
	    compare=&comparem;
		run;
	%end; 
	%if &formatshort = 0 %then %do; 
		proc compare base=&basem
	    compare=&comparem;
		run;
	%end; 
%mend MacroCompareTables; 

Normally, I try to "control" (validate) for all possible misstakes i can come up with. One possible error in this macro is that the tables are not in the work library, any advice on how I could validate for this? 

[andreas_lds]

Some ideas:

/* Assume &base is in work if &base does not contain a libref */
%if %index(&base., %str(.)) = 0 %then %do;
  /* no library specified in &base, prefix work */
  %let base = work.&base;
%end;

/* clone last block for &comapare */

/* no need for having proc compare twice in your code */
%local briefsummary;
%if &formatshort = 1 %then %do;
  %let briefsummary = briefsummary warning;
%end;

proc compare base=&base. compare=&compare &briefsummary;
run;

[ChrisNZ]

I don't understand why you worry about the work library. The table name in &base and &compare should include the library if needed.

Like this?

%macro MacroCompareTables(base, compare, formatshort); 
  %if &formatshort NE 0 and &formatshort NE 1 %then %do; 
    %put NOTE: Parameter formatshort not found and set to 0.;
    %let formatshort=0;
  %end;
  %if ^%sysfunc(exist(&base)) %then %do; 
    %put ERROR: Table &base not found.;
    %return;
  %end;
  %if ^%sysfunc(exist(&compare)) %then %do; 
    %put ERROR: Table &compare not found.;
    %return;
  %end;

  proc compare %if &formatshort %then briefsummary warning;
    base   =&basem
    compare=&comparem;
  run;

%mend MacroCompareTables;