How to create a variable which depends on other variables and their means

[RosieSAS]

Hello,

I have a difficulty to get variables' value from other two variables. I have three continuous variables: x1, x2, x3. 

x2=mean(x1)*(1-x1**2);

x3=(mean(x1)+mean(x2))*(1-x2**2).

Here mean(x1) is the mean of all x1 values, the same as mean(x2). If I use the formula directly in data step, then mean(x1) will equal the current value of x1, not the mean of all x1 values. Is there one can help me figure out how to get the correct values of x2 and x3? Thanks a lot!

Rosie 

[BigD]

I think you will need to calculate the mean values first, then merge them back to the original data, and then do your calculations.

[RosieSAS]

Thanks! I'm wondering whether there is a quicker way? This way needs to use two PROC MEANS and two merges.

[Tom]

It looks strange to change the value of X2 and then reference the MEAN of X2.  Do you want the mean from the original value?  Or the mean of the modified value?

But in general you will need to calculate the means first.  Then you can use them.

For example:

proc summary data=have ;
  var x1 x2 ;
  output out=means mean= /autoname;
run;
data want;
  set have;
  if _n_=1 then set means;
  x2=x1_mean*(1-x1**2);
  x3=(x1_mean+x2_mean)*(1-x2**2);
run;

PROC SQL makes that easier as it will automatically remerge aggregate values onto the detailed observations for you.

proc sql;
create table want as 
  select *
       , mean(x1)*(1-x1**2) as new_x2
       , (mean(x1)+mean(x2))*(1-x2**2) as new_x3
  from have
;
quit;

 Note that the MEAN() function in PROC SQL is the aggregate function.  If you want to use the SAS function in PROC SQL code you must specify at least two arguments so the compiler/parser can tell which one you want.

[RosieSAS]

Sorry that I didn't make my question clear. At first I only have the values of x1, then using x1 to get x2, then using x1 and x2 to get x3.

[Tom · Accepted solution]

---

@RosieSAS wrote:
Sorry that I didn't make my question clear. At first I only have the values of x1, then using x1 to get x2, then using x1 and x2 to get x3.

---

So there is no way to avoid making multiple passes through the data to do that.

PROC SQL syntax is easier to specify since you can use nested sub queries.

proc sql ;
create table want as
select step2.x1
     , step2.x2
     , (step2.x1_mean+mean(step2.x2)*(1-step2.x2**2) as x3
 from (
  select step1.x1
       , step1.x1_mean
       , x1_mean*(1-step1.x1**2) as x2 
   from (
        select have.x1,mean(have.x1) as x1_mean from have
        ) step1
      ) step2
;
quit;

You probably don't need to use all of those aliases (step1,step2) in the variable references, but I just spelled it out in detail so you can see the sequential nature of the steps.