How to align footnote to the left of the table using Proc Tabulate

[mary_mcneill]

Hello,

I am trying to align my footnote to the left of the table. I tried j=left but that aligns it to the left of the margin instead of to the left of the table. Is there a way to align left of the table instead?

/*Syphilis Adverse Outcomes*/
title 'Syphilis Cases with Adverse Outcomes by Month';
options missing=0;
proc tabulate data=work.adverse_outcomes2 missing;
format month monfmt.;
class reportablecondition adverse_outcomes month year / preloadfmt;
table reportablecondition=''*adverse_outcomes='', Year=''*(month='' all)/ printmiss BOX='Adverse Outcomes';
keylabel N=' ' All='Total';
footnote1 '2022 is preliminary data';
footnote2 'Adverse Outcomes includes Syphilis cases where Neuro/Ocular/Otic/Late Clinical Manifestations is indicated as Possible, Likely or Confirmed';
footnote3 'Clinical Manifestations are not mutually exclusive';
footnote4 'Excludes Congenital Syphilis cases';
footnote5 'Data subject to change as additional information is reported';
footnote6 'Source: Ohio Department of Health, STD Surveillance Programs.';
footnote7 "STD Surveillance data reported through &edate. ";
run;

[ChrisNZ · Accepted solution]

You mention left justification, but show centred justification?

In any case, once you write outside of the table, the table's dimensions are not available to align to.

What you can do is create surrounding divisions to align to. I coloured them so you can see where they lie.

  option nocenter;
 title '<div style="padding: 50px; background-color:red" >Title <div>';
/* title2 '<div style="padding: 50px; background-color:green" > <a />';*/
proc tabulate data=SASHELP.CLASS;
class AGE; 
table AGE,n;
run;
footnote2 'Adverse Outcomes includes Syphilis cases where Neuro/Ocular/Otic/Late Clinical Manifestations is indicated as Possible, Likely or Confirmed';
footnote3 '</div></div>';

[Ksharp]

title "Syphilis Cases with Adverse Outcomes by Month";
options missing=0;
ods escapechar='~';
proc tabulate data=sashelp.class missing;
class sex age/ preloadfmt;
var weight;
table sex=""*age="", weight/ printmiss BOX="Adverse Outcomes";
footnote1 j=l "%sysfunc(repeat(~_,115))2022 is preliminary data";
footnote2 j=l "%sysfunc(repeat(~_,115))Adverse Outcomes includes Syphilis cases where Neuro/Ocular/Otic/Late Clinical Manifestations is indicated as Possible, Likely or Confirmed";
footnote3 j=l "%sysfunc(repeat(~_,115))Clinical Manifestations are not mutually exclusive";
footnote4 j=l "%sysfunc(repeat(~_,115))Excludes Congenital Syphilis cases";
footnote5 j=l "%sysfunc(repeat(~_,115))Data subject to change as additional information is reported";
footnote6 j=l "%sysfunc(repeat(~_,115))Source: Ohio Department of Health, STD Surveillance Programs.";
footnote7 j=l "%sysfunc(repeat(~_,115))STD Surveillance data reported through edate. ";
run;