Formatting proc print ods excel footnotes space between table

[kmin87]

ods excel file="\\desktop\sample.xlsx"
style=meadow options(embedded_titles="yes" sheet_interval="none" frozen_headers = '3' sheet_name="Data" EMBEDDED_FOOTNOTES='ON' ABSOLUTE_ROW_HEIGHT=",,,30,30,");
options nobyline;

			proc print data=work.comparison  noobs label;
			var asc /  style(column)={tagattr='format:@' just=c}; 
			var diff1 diff2 diff3  / style={just=c};
			var;

			TITLE1 color=green BOLD "Title";
			FOOTNOTE1 color=black height=1.5 "Prepared by John Smith on &sysdate9.";
			FOOTNOTE2 color=black height=1.5 "Controlled by: Organization";
			FOOTNOTE3 color=black height=1.5 "POC: john.smith@yah.com";
			FOOTNOTE4 color=green BOLD "Title";
			run;
			ods excel close;

There are additional code above to create the work.comparison data but the focus is in the code above to generate the data table in the excel file, sample.xlsx. Sometimes there may be more rows of data rather than one but for this caser there is one row, row 4 in excel file. For the footnotes, how do I create a space between the table from proc print and footnote. and how do I remove the border lines from the footnotes of rows 5-7. And how do I make the font smaller than the table font size or make the table font size bigger?

[SASJedi · Accepted solution]

1. Make your FOOTNOTE1 a blank line to give space between the table and footnotes.

2. Control the point size of the FOOTNOTE fonts with HIEGHT=xxPT.

3. Use JOURNAL style first, so the TITTLE and FOOTNOTE lines get created without borders.

4. Apply your MEADOWS style just before printing the table. 

I used this code:

options nobyline;
ods excel file="C:\temp\sample3.xlsx" 
      style=journal
      options(embedded_titles="yes" sheet_interval="none" 
      frozen_headers = '3' sheet_name="Data" EMBEDDED_FOOTNOTES='ON' 
      ABSOLUTE_ROW_HEIGHT=",,,30,30,");
TITLE1 color=green BOLD "Title";
FOOTNOTE1 "  ";
FOOTNOTE2 color=black height=8pt "Prepared by John Smith on &sysdate9.";
FOOTNOTE3 color=black height=8pt "Controlled by: Organization";
FOOTNOTE4 color=black height=8pt "POC: john.smith@yah.com";
FOOTNOTE5 color=green BOLD "Title";

ods excel style=meadow;
proc print data=sashelp.class(obs=1) noobs label;
   var Name /  style(column)={tagattr='format:@' just=c}; 
   var Age Height Weight / style={just=c};
   var;
run;
ods excel close;

And the Excel file, when printed, looks like this: