Find function with macro variable and arrays

[dera]

Hi,

I would like to know how to use the find function with arrays.

Here is what I have : 

data want; set have;
	y1 = find(var, trim("&yes1"), 'i');
	y2 = find(var, trim("&yes2"), 'i');
	y3 = find(var, trim("&yes3"), 'i');

	n1 = find(var, trim("&no1"), 'i');
	n2 = find(var, trim("&no2"), 'i');
	n3 = find(var, trim("&no3"), 'i');
run;

I would like to optimize my program and do something like this :

data want; set have;
	array y {*} y1-y3;
	do i = 1 to dim(y);
        y(i) = find(var, trim("&yes(i)"), 'i'); 
	end;

	array n {*} n1-n3;
	do i = 1 to dim(n);
        n(i) = find(var, trim("&no(i)"), 'i');
	end;
run;

Can anyone help me with that?

Thank you.

[PaigeMiller]

So apparently you have already created macro variables &yes1 &yes2 &yes3 and &no1 &no2 &no3. Then your loops would need this syntax

y(i) = find(var, trim("&&yes&i"), 'i'); 

[Astounding]

What do you mean by "optimize my program" ?

If you have created your macro variables carefully (by removing leading and trailing blanks) you can make the program run faster by removing the TRIM function.

[dera]

I mean that if I want to make it easier if I decide to add more macro variable. Paige Miller understood what I am looking for but his code does not work. Do you have idea?

[PaigeMiller]

---

@dera wrote:
I mean that if I want to make it easier if I decide to add more macro variable. Paige Miller understood what I am looking for but his code does not work. Do you have idea?

---

We can't help you if the only information you give us is "does not work". Please explain. Please show us the SASLOG. Give us information.

[PaigeMiller]

%do i = 1 %to 3;
    y(&i) = find(var, trim("&&yes&i"), 'i'); 
%end;

Although I am starting to think that there must be easier ways to do this than mixing arrays and macro variables, but since we don't really know what you are doing, it's hard to advise.

[Astounding]

From what you have posted so far, the program would be easier with no macro variables at all.  How do they make anything easier?

[andreas_lds · Accepted solution]

If you insist on using macro-variables, then try:

data want; set have;
	array y {*} y1-y3;
	do i = 1 to dim(y);
          y(i) = find(var, symget(cats('yes', i)), 'i'); 
	end;

	array n {*} n1-n3;
	do i = 1 to dim(n);
          n(i) = find(var, symget(cats('no', i)), 'i');
	end;
run;

Properly created macro-variable don't have trailing blanks.