You want to find all instances of 3+ consecutive zeroes between 10's. When such a series is found you increment the sequence number by 1. But if a shorter series is found you reset the sequence number to 1. Is that correct?
data want (drop=nzero seq);
do Nzero=0 by 1 until (run=10 or eod);
set have end=eod;
end;
if nzero>=3 then seq+1;
else seq=1;
count=seq;
do until(run=10 or eod2);
set have end=eod2;
if run=10 then count=.;
output;
end;
run;
Notes:
- This program assumes that run=10 or 0 - no other values appear, as in your sample data.
- The "do nzero=" loop starts at zero rather than one, so that when the "run=10" record countributes to the increment of nzero, it does not produce an overcount.
- I include the "or eod" and "or eod2" in the "until" conditions to accomodate the possibility that the last record of the dataset does not have run=10.
If you have run values other than 10 and 0, then counting the consecutive records between 10's is no longer the same as counting "run=0" records. You'd have to modify the program to this:
data want (drop=threezeroesfound seq);
do until (run=10 or eod);
set have end=eod;
if lag2(run)=0 and lag(run)=0 and run=0 then threezeroesfound=1;
end;
if threezeroesfound then seq+1;
else seq=1;
count=seq;
do until(run=10 or eod2);
set have end=eod2;
if run=10 then count=.;
output;
end;
run;
