First problem. Your printout is showing DATETIME values and not DATE values.
Is your variable a DATE variable, like your words say, or a DATETIME variable, like your printouts say? That is does it contain counts of days or counts of seconds?
Main problem. It is not at all clear where you came up with the date of 29DEC2028 for PMC. Did you just KNOW that or did your CALCULATE that from some data? If you calculated it then what data did you use? And how did you calculate it.
Let's assume you have this source dataset, let's call it HAVE.
data have;
ConType :$3. Date :date. CP PP MM ;
format date date9.;
cards;
PMC 31May2024 200 200 200
PMC 28JUN2024 235 244 33
PMC 31JUL2024 235 500 654
PMC 30SEP2024 238 234 222
ERC 31JAN2023 109 546 230
ERC 28FEB2023 234 320 777
ERC 31MAR2023 223 111 435
ERC 29SEP2023 187 325 120
;
And you have some other dataset, let's call it DATES, that has variable named ENDDATE that is also a date value.
If the goal is to add extra observations to extend all of the CONTYPE groups to the same end date then do something like this to calculate the maximum enddate and use it to add new observations.
proc summary data=dates ;
var enddate;
output out=lastday max=enddate;
run;
data want;
if _n_=1 then set lastday(keep=enddate);
set have;
by contype;
output;
if last.contype then do;
cp=0; pp=0; mm=0;
do date=date+1 to enddate;
output;
end;
end;
run;
If instead you want to use a different enddate for each CONTYPE then calculate the max(enddate) for each CONTYPE and MERGE the two datasets instead.
proc summary nway data=dates ;
class contype;
var enddate;
output out=lastday max=enddate;
run;
data want;
merge have lastday(keep=contype enddate);
by contype;
output;
if last.contype then do;
cp=0; pp=0; mm=0;
do date=date+1 to enddate;
output;
end;
end;
run;
Click image to register for webinar
