End of the month for a different time zone

[UdayGuntupalli]

All, 
    Here is a question that I am struggling with. I would like to find the last day of the month in a different time zone. I know there are countless examples using intnx() which show how to compute the last day of the month. I tried to apply the same concept as shown in one such example. Here is my code: 

/*%Let T = %sysfunc(tzoneu2s(%sysfunc(tzones2u(%sysfunc(datetime()))),asia/singapore));
%Put Test:  &T;
%Let T1 = %sysfunc(intnx('dtmonth', &T, 0, 'E'));
%Put Test1: &T1;*/

   I receive a warning which says: 

WARNING: Argument 1 to function INTNX referenced by the %SYSFUNC or %QSYSFUNC macro function is out of range.

NOTE: Mathematical operations could not be performed during %SYSFUNC function execution. The result of the operations have been set

to a missing value.

   Alternatively, if I format "T" as a date time as shown below, that results in an errror: 

%Let T = %sysfunc(tzoneu2s(%sysfunc(tzones2u(%sysfunc(datetime()))),asia/singapore),datetime.);
%Put Test:  &T;
%Let T1 = %sysfunc(intnx('dtmonth', &T, 0, 'E'));
%Put Test1: &T1;

ERROR: Argument 2 to function INTNX referenced by the %SYSFUNC or %QSYSFUNC macro function is not a number.

ERROR: Invalid arguments detected in %SYSCALL, %SYSFUNC, or %QSYSFUNC argument list. Execution of %SYSCALL statement or %SYSFUNC

or %QSYSFUNC function reference is terminated.

 Any help or advice is appreciated. Thanks in advance. 

Best 
Uday 

[PaigeMiller]

Do not use quotes inside of %sysfunc

%Let T1 = %sysfunc(intnx(dtmonth, &T, 0, E));

[UdayGuntupalli]

@PaigeMiller,
  Thank you for your response. I updated the code according to your suggestion and still receive the same error. 

%Let T = %sysfunc(tzoneu2s(%sysfunc(tzones2u(%sysfunc(datetime()))),america/los_angeles),datetime.);
%Put Test:  &T;
%Let T1 = %sysfunc(intnx(dtmonth, &T, 0, E));
%Put Test1: &T1;

[PaigeMiller · Accepted solution]

Important rule: do not format your dates or datetimes to be human readable when writing macro code. The only time they need to be formatted for human readability is when you are either inputting the date/datetime or outputting the date/datetime.

%Let T = %sysfunc(tzoneu2s(%sysfunc(tzones2u(%sysfunc(datetime()))),america/los_angeles));

By the way, please don't show us your SASLOG as a (hard-to-read) screen capture. SAS LOG ought to copied as text and pasted into the window that appears when you click on the {i} icon.

[SuryaKiran]

Hello,

Apart from @PaigeMiller suggestion, you need to tell SAS that your are giving datetime vaues.

%Let T = %sysfunc(tzoneu2s(%sysfunc(tzones2u(%sysfunc(datetime()))),asia/singapore),datetime.);
%Put Test:  &T;
/* You need to tell SAS that its a datetime value ("datetime value"dt)*/
/* Since the macro variable T has a value in date time */
%Let T1 = %sysfunc(intnx(dtmonth, "&T"dt, 0, E));
%Put Test1: &T1;

Another approache, leave them as SAS numeric date values and avoid giving the format.

/* In this example the macro varible simply holds numeric value, no format */

%Let T = %sysfunc(tzoneu2s(%sysfunc(tzones2u(%sysfunc(datetime()))),asia/singapore));
%Put Test:  &T;
%Let T1 = %sysfunc(intnx(dtmonth,&T, 0, E));
%Put Test1: &T1;
/* Note: T1 is a numeric value that represent SAS Date, you may later need to apply format to it*/