ERROR: Function name missing in %SYSFUNC or %QSYSFUNC macro function reference.

[Vigneswar]

Hi,

I am trying to create a file name Canada_CM_ Jan_28_2019 .

File is basically extracting the Business name with monday's date of the week.

Below is my code,

%let t=%sysfunc(today());
%let monday=%sysfunc(intnx(week.2,&t,0,b),date9.);
%let outputdate=%substr(&monday,3,3)_%substr(&monday,1,2)_%substr(&monday,6);
%put &outputdate;

%let Business = %sysfunc(scan(Canada_all,1,'_'));
%put &Business;

%let file = %qsysfunc(&Business_CM_ &outputdate);

%put &file;

When run the code I am getting the below error,

WARNING: Apparent symbolic reference BUSINESS_CM_ not resolved.
ERROR: Function name missing in %SYSFUNC or %QSYSFUNC macro function reference.

Any suggestions.

Thanks,

Vigneswar

[RW9]

data _null_;
  want=cats("Canada_CM_",put(month(today()),monname3.),put(day(today(),best.),put(year(today()),best.));
  call symputx('file',want);
run;

Note not tested, but something like that.

[Vigneswar]

%let Business = %sysfunc(scan(Canada_all,1,'_'));

where scan(&output.,1,'_')

This output value is not specific to canada. It is dynamically changing getting resolved by an another macro &output.


Sorry for missing this!

[karolis_b · Accepted solution]

Hi!

It tries to resolve Business_CM macro variable, but you haven't declared it. I'm guessing, you are trying to resolve &Business followed by _CM_ and then date. Try code below. I added . after &Business, also I have changed %sysfunc(scan()) to %scan.

%let t=%sysfunc(today());
%let monday=%sysfunc(intnx(week.2,&t,0,b),date9.);
%let outputdate=%substr(&monday,3,3)_%substr(&monday,1,2)_%substr(&monday,6);
%put &outputdate;

%let Business = %scan(Canada_all,1,_);
%put &Business;

%let file = &Business._CM_&outputdate;

%put &file;

- Karolis

[Vigneswar]

You are right. I missed . while referring Business. It worked now.

Thanks a lot Karolis!

[Kurt_Bremser]

See Maxim 48. Always terminate macro variable references with a dot (&Business.).