Convert string date to date value

[cm3]

I have a variable Enrollment_month - type character, length 8 with value ex:FEB2022. I want to convert this into date format as 20220201. Please help

[Kurt_Bremser]

Since your notation fits most of the DATE9 informat, conversion is easy:

data want;
set have (rename=(enrollment_month=_em));
format enrollment_month yymmddn8.;
enrollment_month = input(cats("01",_em),date9.);
drop _em;
run;

PS I changed your subject line. "Hi" is not descriptive and only makes you look silly.

[cm3]

your solution worked , thank you.
Thanks for updating the title, it was bit confusing in mobile and I missed it

[SASKiwi · Accepted solution]

data Want;
  Enrollment_month = 'FEB2022';
  Enrollment_date = input('01' !! Enrollment_month, date9.);
  format Enrollment_date yymmddn8.;
  put _all_;
run;

[cm3]

Also I was wondering how would we convert if enrollment_month is type date with same value?? Pls confirm

[Kurt_Bremser]

If it is already a SAS date value, you only need to change the assigned format, e.g. with PROC DATASETS for the dataset, or with a FORMAT statement (or FORMAT= option in PROC SQL) wherever needed.

[SASKiwi]

"If enrollment_month is type date with same value" - A numeric variable can't contain the same value as "FEB2022" as that is character data. The closest you can get is this, where you define it as a date based on 01 Feb 2022:

data Want;
  Enrollment_month = '01FEB2022'd;
  Enrollment_date = Enrollment_month; 
  format Enrollment_month date9. Enrollment_date yymmddn8.;
  put _all_;
run;

[Kurt_Bremser]

PS there is no type "date" in SAS. SAS has only two types of variables, character and numeric.

Dates are stored in numeric variables, as counts of days with 1960-01-01 as day zero, and with a proper format assigned to make the raw value human-readable.

[Ksharp]

Also could try MONYY. informat.

data Want;
Enrollment_month = 'FEB2022';
Enrollment_date = input(Enrollment_month, monyy9.);
format Enrollment_date yymmddn8.;
put _all_;
run;