Check if current time less than a value

[hhchenfx]

Hi,

I want to compare current time with '4:55't as below but my code is not working.

Can you please help to fix?

Thanks,

HHC

%MACRO _BREAK() ;
%let current_time = time(); /* Get the current time */

%IF &current_time < '4:55't %then %do;
	%put "print before ";
	%END;
%ELSE %do;
	%put "print after";
	%END;

%Mend;

%_BREAK();

[Kurt_Bremser]

%let current_time = time(); /* Get the current time */

Here, you assign the text time() to the macro variable (not the result of the function!). If you want to execute a data step function in macro code, you need to use %SYSFUNC:

%let current_time = %sysfunc(time());

[SASKiwi]

It's a lot easier not using macro logic - not sure why you need a macro at all:

%MACRO _BREAK() ;

data _null_;
  if time() < '4:55't then putlog "print before ";
  else putlog "print after";
run;

%Mend;

%_BREAK();

[LynnP_sas · Accepted solution]

Greetings,

I made the following modifications to your code:

%MACRO _BREAK() ;

%let current_time = %sysfunc(time()); /* Get the current time */

%put curr is &current_time;

%IF %sysevalf(&current_time < '20:55't) %then %do;

%put "print before ";

%END;

%ELSE %do;

%put "print after";

%END;

%Mend;

%_BREAK();

The problems you were having are due to the macro facility only understanding text.

[hhchenfx]

Thank you so much for helping!

HHC