A few thoughts:
1. It appears that you copied the code from https://blogs.sas.com/content/iml/2019/11/13/create-biplots-sas.html It is always helpful if you cite references so that others can see where the code came from and read the accompanying discussion.
2. Your first mistake is that you didn't add an ID variable to your data set. Re-read the blog post to see how to add an ID variable.
3. The second problem is that three of your variables are constant. Freidnly's %BIPLOT macro does not handle constant variables, so you must remove them from the analysis.
%let VarNames = StC NA SP PGH BH LC LS LP NFA FP CC AC SE MS
CP CM AS FCI FCM FS FSPA NBF FSBE FBEA
FC FSr SC
NSF GU PH MLL MLW PHF CWF FL FW FWt FT FPP
DFt DFl DFF TSWt FPK Yd;
proc means data=chili;
var &VarNames;
run;
/* Note that the MS, FBEA, and SC variables are constant.
You need to exclude those variables.
*/
%let VarNames = StC NA SP PGH BH LC LS LP NFA FP CC AC SE
CP CM AS FCI FCM FS FSPA NBF FSBE
FC FSr
NSF GU PH MLL MLW PHF CWF FL FW FWt FT FPP
DFt DFl DFF TSWt FPK Yd;
%let FACTYPE = SYM; /* options are GH, COV, JK, SYM */
title "Biplot: &FACTYPE, STD";
%biplot(data=chili,
var=&VarNames,
id=id,
factype=&FACTYPE, /* GH, COV, JK, SYM */
std=std, /* NONE, MEAN, STD */
scale=1, /* if you do not specify SCALE=1, vectors are auto-scaled */
out=biplotFriendly,/* write SAS data set with results */
symbols=circle dot, inc=1);
/* transpose from long to wide */
data Biplot;
set biplotFriendly(where=(_TYPE_='OBS') rename=(dim1=Prin1 dim2=Prin2 _Name_=_ID_))
biplotFriendly(where=(_TYPE_='VAR') rename=(dim1=vx dim2=vy _Name_=_Variable_));
run;
proc sgplot data=Biplot aspect=1 noautolegend;
refline 0 / axis=x; refline 0 / axis=y;
scatter x=Prin1 y=Prin2 / datalabel=_ID_;
vector x=vx y=vy / datalabel=_Variable_
lineattrs=GraphData2 datalabelattrs=GraphData2;
xaxis grid offsetmin=0.1 offsetmax=0.2;
yaxis grid;
run;
Click image to register for webinar
