proc transpose idlabel

[RickM]

Hi all,

I am having some trouble with using the idlabel statement with a numeric value. When I run the following code I end up with labels with leading blank spaces.

[pre]
data one;
input Subject Period Timep Time Val;
datalines;
1 1 1 0 1
1 1 2 .5 3
1 1 3 1 5
1 1 4 1.5 7
1 1 5 2 9
1 2 1 0 2
1 2 2 .5 4
1 2 3 1 6
1 2 4 1.5 8
1 2 5 2 10
2 1 1 0 1
2 1 2 .5 3
2 1 3 1 5
2 1 4 1.5 7
2 1 5 2 9
2 2 1 0 2
2 2 2 .5 4
2 2 3 1 6
2 2 4 1.5 8
2 2 5 2 10
;
run;

proc transpose data=one out=two(drop=_NAME_) prefix=HR;
by subject period;
id timep;
idlabel time;
run;

proc print data=two label noobs;
run;

[/pre]

I have also tried making time a character variable of length 3 but I still end up with leading blanks.

Any tips would be appreciated.

[sfsdtegsdsdgdffhgfh]

Rick,

Try this


data one;
set one;
time2 = left(put(time,best12.));
run;

proc sort data = one;
by subject period;
run;

proc transpose data=one
out=two(drop=_NAME_) prefix=HR;
by subject period;
id timep;
idlabel time2;
run;
proc print data=two label noobs;
run;

GL.

[RickM]

Thanks!

That works perfectly.