You can only BREAK on GROUPing or ORDERing variables when doing PROC REPORT

[imdickson]

Im learning PROC REPORT by following guides that i found on google.

However, i got this error when i try doing it:

You can only BREAK on GROUPing or ORDERing variables

with the code below:

proc report data=ALFRED.shoes;
COL Name Age Country Nationality Agemean;
DEFINE Age /analysis mean;
DEFINE Country /DISPLAY 'Country of Origin';
DEFINE Agemean /COMPUTED 'Age Mean';
COMPUTE Agemean;
Agemean=Age.mean;
ENDCOMP;
BREAK AFTER Nationality / SUMMARIZE;
run;

I read alot of guides about BREAK AFTER, and im still very confused about the purpose and usage of it. Can anyone explain this in a simpler way?

[mohamed_zaki]

proc report data=ALFRED.shoes;
COL Name Age Country Nationality Agemean;
DEFINE Nationality /order;
DEFINE Age /analysis mean;
DEFINE Country /DISPLAY 'Country of Origin';
DEFINE Agemean /COMPUTED 'Age Mean';
COMPUTE Agemean;
Agemean=Age.mean;
ENDCOMP;
BREAK AFTER Nationality / SUMMARIZE;
run;

[RW9]

Hi,

Just to add two things there, you can define the variable as either group or order depending on wht you are doing.  A further note is that code formatting makes things a lot easier to read - consistent capitilisation indetations etc. as in (and you can use the {i} icon above the post to add code):

proc report data=alfred.shoes;
  columns name age country nationality agemean;
  define name         / display 'Name';
  define age          / analysis mean;
  define country      / display 'Country of Origin';
  define nationality  / group 'Nationality';  /* Or order */
  define agemean      / computed 'Age Mean';

  compute agemean;
    agemean=age.mean;
  endcomp;

  break after nationality / summarize;
run;

[himself]

The variable listed on the BREAK statement is not defined as GROUP or
ORDER.


Solution:
Remove the BREAK statement or change the usage on the DEFINE
statement of that variable to GROUP or ORDER.