Hi:
If you want to do this using SAS/Graph, then you can use an ANNOTATE data set to write the letters in a semi-circle. There's an annotate example of putting starts in a full circle -- this program is modified from that to place the letters of your name in a semi-circle.
It's probably not as pretty as WordArt or PaintShop could do, but it -is- possible. You'll have to read in the ANNOTATE and GANNO documentation to see all the possible ways you could change the ANNOTATE data set.
cynthia
[pre]
/* set the graphics environment */
goptions reset=all border;
** at every 15 degree interval between 0 and 180, write a letter of your name;
proc format;
value ltr
0 = 'i'
15 = 'r'
30 = 'u'
45 = 'p'
60 = 'p'
75 = 'u'
90 = 'M'
105 = 'h'
120 = 'd'
135 = 'o'
150 = 'n'
165 = 'i'
180 = 'V';
run;
data semicircle;
length function color style $ 8 text $ 30;
retain xsys ysys hsys '3';
/* draw the frame */
function='frame'; output;
/* define the footnote */
function='label'; x=92; y=5; text='SemiCIRCLE';
style='swiss'; size=3; position='5'; output;
/* define the title */
x=50; y=90; text='Semi-Circle Text';
style='swissb'; size=6; output;
/* draw the background */
function='move'; x=20; y=30; output;
function='bar'; x=80; y=80; color='white';
line=3; style='solid'; output;
/* draw the semi-circle of letters */
do ltr_ang=0 to 180 by 15;
ltr = put(ltr_ang,ltr.);
function='piecntr'; x=50; y=55; size=15; output;
function='piexy'; size=1; angle=ltr_ang; output;
function='cntl2txt'; output;
function='label'; style='swissb'; text=ltr;
angle=0; color='black'; size=3; x=.; y=.;
output;
end;
run;
ods listing;
ods html path='c:\temp' (url=none)
gpath='c:\temp' (url=none)
file='annoexamp.html' style=sasweb;
goptions device=gif;
/* generate the output from */
/* the Annotate data set */
proc ganno annotate=semicircle;
run;
quit;
ods html close;
[/pre]