proc reportの一部のヘッダー部のみ左寄せで表示したい

[sasone]

以下を実行しますと名前(NAME)の変数部分はデフォルトで左寄せに表示されるのですが、
ヘッダー部は中央揃えになっています。
名前(NAME)のヘッダー部を左寄せにしたいのですが可能でしょうか(年齢・身長のヘッダー部は中央揃えのままで)。

ods tagsets.rtf file=".\class.rtf";
proc report data=SASHELP.CLASS nowd;
    column NAME AGE HEIGHT;
    define   NAME    / display;
    define   AGE       / display;
    define   HEIGHT  / display;
run;
ods tagsets.rtf close;

以上、ご教示のほど何卒よろしくお願いいたします。

[yu_sas]

DEFINEステートメントのSTYLE=オプションでlocationをHEADERにすることで指定が可能です。

    define   NAME    / display style(header)=[just=l];

[sasone]

yu_sasさま

早速のご回答、誠に有難うございました。
"名前"のヘッダーの上に更に"投与群"のヘッダーが載っていたのですが、
この"投与群"ヘッダーを左寄せにするにはどのようにしたらよろしいでしょうか。

ods tagsets.rtf file=".\class.rtf";
proc report data=SASHELP.CLASS nowd;
  column ("投与群" NAME) ("背景" AGE HEIGHT);
  define NAME / display "名前" style(header)=[just=l];
  define AGE / display "年齢";
  define HEIGHT / display "身長";
run;
ods tagsets.rtf close;

度々で済みません。

[yu_sas]

COLUMNステートメントで指定したヘッダについては左寄せするオプションはないと思います。

ODS ESCAPECHARステートメントのSTYLE関数でも、反映させることはできないようです。

※文字色のように文の途中から変更可能なものは指定できました。

スマートな方法ではありませんが、文字列の後ろに空白を挿入するなどで疑似的には可能です。

ods escapechar="^";
proc report data=SASHELP.CLASS nowd;
  column ("投与群^{nbspace 5}" NAME) ("背景" AGE HEIGHT);

[sasone]

yu_sasさま

早速に有難うございました。
半角スペースを後ろに6つ打ち込むと丁度よくなりました。
ods tagsets.rtfを用いる場合は、半角スペースで調整させて頂きます。

[daipdo · Accepted solution]

SASONE様

お世話になります。daipdoです

rtf出力時にods rtfを使うといけるようです。ods target.rtfとやってることは同じですが、理屈はわかりません･･･

columnステートメントにスタイルで左詰を指定しています。

一度実行して見てもらえますでしょうか(再現性があるかが非常に不安です)

ods rtf file=".\class3.rtf";
ods escapechar = "^" ;

proc report data=SASHELP.CLASS nowd;
  column ("^S={just=left}投与群" NAME) ("背景" AGE HEIGHT);
  define NAME / display "名前" style(header)=[just=l];
  define AGE / display "年齢";
  define HEIGHT / display "身長";
run;

ods rtf close;

[sasone]

daipdoさま

ods rtfに切り替えたところ、PC-SASでもSAS OnDemandでも再現できました。
ods rtfでの使用を検討してみます。
ありがとうございました。