Hi:
The default split character for a header is the slash / character. So you might try setting a label for your variable of:
label sales='Sales Amount /(inc. Sales Tax)';
The issue will then become that for procedures that do not have a split character, you will see the / in the label. So, either change the label inside the List Report task, or live with the / in other places.
When this label is distracting under an ACROSS variable, in code, you would turn the label to ' ' (quote space quote). I don't know if the List Report Wizard will allow you to do that. As you can see in example 1b, in the code below, using quote-space-quote in the SALES header UNDER an ACROSS item (as in PRODUCT,SALES )produces undesirable results.
I know you don't want to run code, but observe the difference if you do run the program below -- in the column headers based on the order of the items in the COLUMN statement. If you rearrange the items in the COLUMN statement so that sales, comes first, as in SALES,PRODUCT (list the analysis variable first) -- then you can use quote-space-quote to get rid of the entire blank row that REPORT would create.
So to insert the split character should be easy, since I assume that the List Report Task does not alter the default of / . If they have changed the split character, you would see it in the code as:
proc report data=sashelp.shoes nowd split='*'; (if they change it)
OR
proc report data=sashelp.shoes nowd split='/'; (if they just explicitly use the default)
The List Report Task is meant to generate simple reports easily -- reports that you can't generate with PROC PRINT, such as summary reports and simple ACROSS reports. But, to streamline the column headers or do more complex things in your report, I think you have to do in code.
cynthia
ods html file='c:\temp\header1.html' style=egdefault;
proc report data=sashelp.shoes nowd;
where region contains 'Europe';
title '1a) Default Label';
column region product,sales;
define region / group;
define product / across;
define sales / sum 'Total/Sales';
run;
proc report data=sashelp.shoes nowd;
where region contains 'Europe';
title '1b) Default Label with space';
column region product,sales;
define region / group;
define product / across;
define sales / sum ' ';
run;
proc report data=sashelp.shoes nowd;
where region contains 'Europe';
title '2) Rearranged Variables and Label with space';
column region sales,product;
define region / group;
define product / across 'Total Sales/Based on Product';
define sales / sum ' ';
run;
ods html close;
