libname defaulting to V6 and then not working

[dleduc]

I am running version 9.4 of SAS on my Windows 10 desktop.  When I use a libname statement as in

libname sss "C:\Users\dleduc\Documents\data\loblolly\sudden_sawlog";
run;

I get the following  response:

NOTE: The V6 engine on this host is limited to read-only access of SAS data files without index
optimization. V6 data files cannot be created or updated and V6 catalogs cannot be read.
NOTE: Libref SSS was successfully assigned as follows:
Engine: V6
Physical Name: C:\Users\dleduc\Documents\data\loblolly\sudden_sawlog

I then attempt to use this library to store a dataset and it acts like it says above.   I cannot write to it.

ERROR: Write access to member SSS.NEW.DATA is denied.
NOTE: The SAS System stopped processing this step because of errors.

I have no interest in creating a V6 dataset like several of the other people I have read responses from.  I just want a dataset that I can keep and then examine since I have something else funny going on in my analysis program.  If V9 is supposed to be the default, why is my system defaulting to V6?

Thank you for any help that you can provide.

[SASKiwi]

The fact that you can't write to that folder means your Windows permissions on it is set to read-only. You can confirm this by opening the folder in Windows Explorer and checking the Properties. You have to fix this in Windows  - it is not a SAS problem. Refer to your IT help desk if you can't fix it. IT often locks down some PC hard drive folders so staff can't delete anything by accident.

Try creating a brand-new folder and assigning a new LIBNAME to it. That should work as you expect. 

[JackHamilton]

Is there a v6 data set, or something that SAS might think to be a v6 data set, in that directory?  If so, SAS might think you don't want the default engine.  You could try explicitly specifying an engine in the libname statement.

[dleduc]

 Being able to write to the folder is not the problem.  I can write text files to it all day long.  The problem is that I cannot write to a V6 file as the error message says.

[Kurt_Bremser · Accepted solution]

Inspect the directory. If there is a file with .ssd or .ssd01 extension in it, this causes the switch to V6.

In any case, force the engine:

libname sss v9 "C:\Users\dleduc\Documents\data\loblolly\sudden_sawlog";

Note that LIBNAME is a global statement, so no RUN is necessary.

[dleduc]

Actually the file that was in the folder had an extension of .sd2.  I had last worked with this data about 25 years ago so I don't even know what version of SAS I was using then.  Removing that file solves the problem.

[Kurt_Bremser]

That's also one of the filename extensions used for V6 datasets on Windows. If you have something likle that, you can preserve the data for future use:

libname sss v9 "C:\Users\dleduc\Documents\data\loblolly\sudden_sawlog";
libname sss_old v6 "C:\Users\dleduc\Documents\data\loblolly\sudden_sawlog";

proc copy inlib=sss_old outlib=sss;
run;

proc datasets nolist lib=sss_old kill;
quit;

libname sss_old clear;

[Tom]

You must have some version 6 datasets in that directory already. 

Just change the LIBNAME statement to be explicit about which engine you want to use.

Use BASE engine to use the default for your current SAS version.

libname sss base "C:\Users\dleduc\Documents\data\loblolly\sudden_sawlog";

If you need to read those old V6 dataset point a different libref at that same directory and use that.

libname sssv6 v6 "C:\Users\dleduc\Documents\data\loblolly\sudden_sawlog" access=readonly;