Changing character values to numeric values

[RandiRyterman]

I have a SAS dataset with a variable called LENGTH, which describe the length of a fishing line.  But some of the values have a ',' instead of a '.' to designate a decimal point, so SAS read this variable as a character variable.  How do I replace all ',' with '.' and convert the variable to numeric?

[Reeza · Accepted solution]

Use TRANSLATE to replace the commas with periods.

var_char = translate(var_char, ".", ",");

USE INPUT to convert character to numeric 

Var_Num = input(var_char, best12.);

[Ksharp]

Canyou post some data?

Var_Num = input(var_char, ??  best12.);

[Patrick]

If you're reading the data from a text file then you could also do something like below:

proc format;
  invalue mixedComma
    low-high = [comma.]
    other    = [commax.]
  ;
quit;

data test;
  infile datalines dsd dlm=' ' truncover;
  input var :mixedComma.;
  datalines;
10.2
10,2
10
;
run;

[Ksharp]

Patrick,

I would do this.

data test;
  infile datalines dsd dlm=' ' truncover;
  input var $;
  if find(var,',') then fmt='commax32.';
   else fmt='best32.    ';
  new=inputn(var,fmt);
  datalines;
10.2
10,2
10
;
run;