I am trying to create a cover page that has an image and text appearing side by side. The code I currently have places the first line at the end of the image, put then continues on below it. How can I get them to appear inline?
/* cover page */
title j=r color=white bcolor=&Dblue height=10pt font='Arial' "NCAA Football Rules Committee Report ";
ods rtf text="^S={just=c} NCAA Football Rules Committee Meeting^n Injury Surveillance Report^4n";
ods rtf text= "^S={just=l cellwidth=5in preimage='C:/Users/Todd/Dropbox/Datalys/Rules Committee Report/rc_title.png'}
^S={just=l vjust=t cellwidth=3in} Submitted to: ^n
NCAA Women's Softball Rules Committee^4n
Submitted by:^n
Datalys Center for Sports Injury Research and Prevention^n
401 West Michigan Street, Suite 500^n
Indianapolis, IN 46202^n
855-832-4222^4n
Report Date: n/a";
footnote j=c color=white bcolor=&Dblue height=8pt font='Arial' "Datalys Center | 401 West Michigan Street, Suite 500 | Indianapolis, Indiana 46202 | 855-832-4222";
How it looks:
This is rough and untested obviously. Play with the settings. You can adapt for rtf
ods escapechar='^';
ods _all_ close;
options nonumber nodate orientation=portrait papersize=letter nocenter
leftmargin=.5in rightmargin=.5in topmargin=.5in bottommargin=.5in;
ods pdf file="~/img/fname.pdf" dpi=300 notoc;
/* start the absolute layout for the page */
ods layout absolute;
ods region x=0.0in y=0.0in height=10in width=7in ;
ods pdf text="^S={}";
ods region x=0.0in y=0in height=1in width=7in ;
ods pdf text="^S={font=('Arial', 10pt) just=r foreground=white backgroundcolor=blue} NCAA Football Rules Committee Report^S={} ";
/* ods pdf text="^S={just=r} NCAA Football Rules Committee Report^S={} "; */
ods pdf text="^S={just=c} ^n^n NCAA Football Rules Committee Meeting^n Injury Surveillance Report^4n^S={}";
ods region x=0.0in y=1in height=6in width=5in ;
ods graphics on / noborder height=5.8in width=4.9in scale=on;
ods pdf text= "^S={just=l cellwidth=5in preimage='~/img/test.png'} " ;
ods graphics off;
ods region x=4.75in y=2.5in height=6in width=2.75in ;
ods pdf text= "^S={just=l vjust=t cellwidth=3in} Submitted to: ^n
NCAA Women's Softball Rules Committee^4n
Submitted by:^n
Datalys Center for Sports Injury Research and Prevention^n
401 West Michigan Street, Suite 500^n
Indianapolis, IN 46202^n
855-832-4222^4n
Report Date: n/a";
ods region x=0.0in y=9in height=.5in width=8in ;
ods pdf text="^S={just=c foreground=white backgroundcolor=blue}
Datalys Center | 401 West Michigan Street, Suite 500 | Indianapolis, Indiana 46202 | 855-832-4222 ^S={}";
ods layout end;
ods pdf close;
Are you ready for the spotlight? We're accepting content ideas for SAS Innovate 2025 to be held May 6-9 in Orlando, FL. The call is open until September 25. Read more here about why you should contribute and what is in it for you!
Learn how use the CAT functions in SAS to join values from multiple variables into a single value.
Find more tutorials on the SAS Users YouTube channel.