Hi:
When I run a version of your code, I get the following message in the log:
[pre]
Unrecognized option: WRAPTEXT
[/pre]
and when I use the doc='Help' suboption, I do not see WRAPTEXT as a valid suboption. So, I'm not sure what to suggest there.
However, when I run a version of your program (limited to 2 regions with long values that should wrap), I DO see wrapping and the height of the cell does autofit and expand.
My recommendation would be that you open a track with Tech Support on this issue.
I ran the code below in SAS 9.2 with TAGSETS.EXCELXP version: v1.94, 09/09/12
cynthia
[pre]
ODS LISTING CLOSE;
%let customer_number =111111;
data shoes;
set sashelp.shoes;
** select only some region values that should wrap;
where region in ('Western Europe', 'Central America/Caribbean');
output;
if _n_ = 1 then do;
region = 'An Extra Row';
product= 'To Repeat';
output;
output;
output;
end;
run;
proc sort data=shoes;
by region product;
run;
** added .XLS to file name, added doc='Help' to suboptions, removed duplicate suboptions and extra ODS statement;
ODS TAGSETS.EXCELXP FILE="c:\temp\wrap.xls"
STYLE=styles.printer
OPTIONS( doc='Help' EMBEDDED_TITLES='yes'
SHEET_INTERVAL = 'none'
WIDTH_FUDGE ='0.75'
SHEET_NAME = "&customer_number"
DEFAULT_COLUMN_WIDTH="10,0,8,8,8,8,8,8,8"
FITTOPAGE = 'yes'
PAGES_FITWIDTH = '1'
Pages_FitHeight = '100'
FROZEN_HEADERS = 'yes'
FROZEN_ROWHEADERS = 'yes'
GRIDLINES = 'no'
AUTOFIT_HEIGHT = 'yes'
PRINT_FOOTER = 'Page: &P of &N'
ROW_REPEAT = '1 - 4' FROZEN_HEADERS = '1 - 4'
WRAPTEXT = 'yes' ); /* this suboption is unrecognized */
title;
%*------ Create Main Report in a format that EXCEL can read and render;
proc report data=shoes split='*' nowd
style(header) =[font_size=9pt font_weight=bold font_face=Arial borderwidth=1pt
cellspacing=0pt cellpadding=1pt]
style(column) =[font_size=9pt font_face=Arial borderwidth=1pt
cellspacing=0pt cellpadding=1pt];
columns region product;
define region / display "Region" style(column)={outputwidth=0.5in font_face=arial };
define product / display "Product" style(column)={outputwidth=0.5in font_face=arial };
compute region;
if region = 'An Extra Row' then do;
call define(_row_,'style','style=Header');
end;
endcomp;
run;
title;
%*------ CLOSE ODS TAGSETS.EXCELXP;
ODS TAGSETS.EXCELXP CLOSE;
ODS LISTING ;
[/pre]