Hi:
I believe the other issue you may be running into is one of understanding which attributes are appropriate to change. Look at the table entitled "Style Attributes and their Values".
http://support.sas.com/documentation/cdl/en/odsug/61723/HTML/default/a002972093.htm (9.2 version)
http://support.sas.com/onlinedoc/913/getDoc/en/odsug.hlp/a003079951.htm (9.1.3 version)
In this doc table, you will see, for example, that "FRAME=" is only supported at the TABLE level. That means it would be inappropriate to try to set FRAME on a particular cell in a table. Similarly, the CELLPADDING attribute is a TABLE level attribute.
So, depending on what you are trying to do, it may just not be possible to alter the cells the way you want with anything other than RTF control words.
And now, the good news (I hope), in the program below, I've shown some very simple kinds of things that you can do with a STYLE template in 9.1.3 and RTF control words. Note the use of the BOXIT style element in the CALL DEFINE for the WEIGHT variable. Compare that to the way the RTF control words were used to format the HEIGHT cell for Robert. And, also note how the "\brdrt\brdrs " were put directly into the header text for the AGE, HEIGHT and WEIGHT variables
This program uses almost all the RTF control words that I know. So, for fancier control words or other formatting, you may need to look to the RTF specification for more help. But, if you supplement this with the user group papers (which were all mostly 9.1.3 papers), you should be able to achieve quite a bit.
Of course, I say that not knowing what RTF control words you've tried. One simple thing that may have held you up is that if you are using RTF control words then you MUST also use the PROTECTSPECIALCHARS=OFF style attribute -- so SAS doesn't try to do you a favor and protect any of the special RTF controls (like the \, the {} or the ~).
cynthia
[pre]
ods path work.temp(update)
sashelp.tmplmst(read);
proc template;
define style styles.my913style;
parent=styles.journal;
style Header from Header /
protectspecialchars=off;
style myothercell from cell/
pretext='\b\i'
posttext='\b0\i0'
protectspecialchars=off;
style boxit from Data/
pretext='\box\brdrs '
font_face='Arial'
font_size=9.5pt
protectspecialchars=off;
end;
run;
ods listing close;
ods rtf file='c:\temp\use_RTF_ctrl.rtf' style=my913style;
proc report data=sashelp.class nowd
style(columnn)={protectspecialchars=off};
column name ('\brdrb\brdrs {Spanning Header}' age height weight);
rbreak after / summarize
style={pretext='\brdrt\brdrs ' protectspecialchars=off};
define name / style(header)=myothercell 'Name';
define age / style(header)=header '\brdrt\brdrs {Age}';
define height / style(header)=header '\brdrt\brdrs {Height}';
define weight / style(header)=header '\brdrt\brdrs {Weight}';
compute height;
if name = 'Robert' then do;
call define(_col_,'style',
'style={pretext="\box\brdrs " }');
end;
endcomp;
compute weight;
if weight.sum gt 120 and _break_ = ' ' then do;
call define(_col_,'style','style=boxit');
end;
endcomp;
run;
ods rtf close;
[/pre]