SGPLOT Annotation for extreme value

[bijayadhikar]

Hi,

Trying to see if there is a away to highlight extreme value point (in this case if value >5) to be marked with red circle or change line color to red.

Data have;
length zone $6;
Input zone RepDate case trend;
informat RepDate ANYDTDTE10.;
FORMAT Repdate mmddyy10.;
Datalines;
A 01/16/2021 1 4.3
A 01/17/2021 1 3.9
A 01/18/2021 12 3.3
A 01/19/2021 16 4.0
A 01/20/2021 2 4.4
A 01/21/2021 5 3.9
A 01/22/2021 6 6.1
;
run;

proc sgplot data=have noautolegend;
vline RepDate / response=trend lineattrs=(color=grey thickness=3 PATTERN=SHORTDASH);

run;

[Rick_SAS]

One way is to use a DATA step to find the outliers (using whatever criterion you want) and then overlay those points as red markers. To do that, you should use the SERIES statement instead of the VLINE statement to draw the line. I think the following is self-explanatory, but write back if the steps are not clear:

Data have;
length zone $6;
Input zone RepDate case trend;
informat RepDate ANYDTDTE10.;
FORMAT Repdate mmddyy10.;
Datalines;
A 01/16/2021 1 4.3
A 01/17/2021 1 3.9
A 01/18/2021 12 3.3
A 01/19/2021 16 4.0
A 01/20/2021 2 4.4
A 01/21/2021 5 3.9
A 01/22/2021 6 6.1
;
run;

data Outliers;
set Have(rename=(trend=Outlier));
if Outlier>5;
run;

data All;
set Have Outliers;
run;

proc sgplot data=All noautolegend;
series x=RepDate y=trend / markers lineattrs=(color=grey thickness=3 PATTERN=SHORTDASH);
scatter x=RepDate y=Outlier / markerattrs=(symbol=CircleFilled size=10 color=red);
refline 5 / axis=y label="Cutoff";
run;

[bijayadhikar · Accepted solution]

@Rick_SAS 

I change vline to needle, and used X/Y series as per your suggestion. It did work perfectly as I wanted.

Much appreciated!