Hi:
The best way to control this on SAS OnDemand for Academics is to
1) put your proc freq and your corr into ONE program file tab (not in 2 editor tabs). Each editor tab has 1 results window. If you have 3 procedure steps in one program, then all the output will show in THAT results window. but if you have the PROC FREQ in one tab and the PROC CORR in another tab, then you will have to switch between the tabs for each procedure to see the results. Your output from your programs is NOT cumulative. Every time you run a program in the Editor, your previous program results are overwritten by the new results from the same program editor tab. So this is how SAS Studio operates.
Another approach is:
2) take full control of your output and use the Output Delivery system. Here's some code to try:
ods html path='/home/<userID>/' file="myreport.html";
proc print data=sashelp.class(obs=10);
title '1 PROC PRINT';
run;
proc freq data=sashelp.class;
title '2 PROC FREQ';
tables age;
run;
proc tabulate data=sashelp.class;
title '3 PROC TABULATE';
class age sex;
var height;
tables age all,
sex*mean*height;
run;
proc corr data=sashelp.class sscp cov plots=matrix;
title '4 PROC CORR';
var height age;
with weight;
run;
ods html close;
With this approach, you take "full control" of the output by using a set of ODS statements around all the output you want to have saved in one output file. You will write this output to your "home" folder. If you right click on Files (Home) and choose Properties, you'll see your unique userID to put in the path option. Then, after the program runs, you can see the output in your Files (Home) location so then if you change the program and you want to have both outputs available, the second time you run the program, just change the name in the FILE= option.
Hope this helps explain some options.
Cynthia
