Rename Changes Format

[trevand]

I had a problem when I renamed a date variable. The format was changed and the new variable could not be used as a date variable. Does this happen to all rename variables or only to data variables?

[PaigeMiller]

When I try this, I don't see the problem you described. Here is my code. Please show us your code.

data test;
    date='01JAN2024'd;
    format date date9.;
run;

data rename;
    set test(rename=(date=renamed_date));
run;

[trevand]

it seems that it's only problematic when I use rename outside of the set statement:

data test;
    date='01JAN2024'd;
    format date date9.;
run;

data rename;
 set test
rename date=renamed_date;
year=year(renamed_date);
run;

the year function gives me an empty column.

[Tom · Accepted solution]

You just have the order of operations confused.

The RENAME statement tells SAS to change the name when it writes the OUTPUT.  During the current data step the name is not yet changed, so use its actual name.

I usually like to place RENAME/DROP/KEEP statements at the END of the data step.  It helps keep it clearer about when they are really applied.

data rename;
  set test;
  year=year(date);
  rename date=renamed_date;
run;

Make sure to read the LOG. 

Your code will generate warnings and important notes.

6    data rename;
7      set test;
8      rename date=renamed_date;
9      year=year(renamed_date);
10   run;

NOTE: Variable renamed_date is uninitialized.
WARNING: Variable renamed_date already exists on file WORK.RENAME.
NOTE: Missing values were generated as a result of performing an operation on missing values.
      Each place is given by: (Number of times) at (Line):(Column).
      1 at 9:8
NOTE: There were 1 observations read from the data set WORK.TEST.
NOTE: The data set WORK.RENAME has 1 observations and 2 variables.
NOTE: DATA statement used (Total process time):
      real time           0.00 seconds
      cpu time            0.01 seconds

[ballardw]

---

@trevand wrote:

it seems that it's only problematic when I use rename outside of the set statement:

data test;
    date='01JAN2024'd;
    format date date9.;
run;

data rename;
 set test
rename date=renamed_date;
year=year(renamed_date);
run;

the year function gives me an empty column.

---

When you abuse syntax expect unexpected results. Your data step should read either (semicolon after test)

data rename;
 set test ;
rename date=renamed_date;
year=year(renamed_date);
run;

Or with proper () for data set options

data rename;
 set test (rename=( date=renamed_date));
year=year(renamed_date);
run;

Your data step as shown does not actually run:

842  data rename;
843   set test
844  rename date=renamed_date;
                -
                22
                76
ERROR 22-322: Syntax error, expecting one of the following: CUROBS, END, INDSNAME, KEY, KEYRESET,
              KEYS, NOBS, POINT.

ERROR 76-322: Syntax error, statement will be ignored.

845  year=year(renamed_date);
846  run;

If you have a "rename" data set then it is the result of different code. So perhaps not surprising that a format definition did not survive.

[ballardw]

If you can provide an example data set in the form of working data step code to create 10 or so observations and the code the renamed the date variable in that data set that has this behavior we could make an attempt to describe what happened.

I.e can you duplicate the behavior consistently. I am going out on a limb and guessing that likely you can't OR something more than a simple rename is involved.