How to compute time distance for longitudinal data in SAS

[trungdungtran]

Hi all,

I have a longitudinal data. Each subject is repeatedly measured over time:

data origin;
	input ID Time;
	cards;
		12	3
		12	5
		12	18
		16	7
		16	25
		16	28
		16	44
	;
run;

I would like to compute time distance. For the first measurement, time distance is set at 0. From the second time point, time distance is computed by subtracting the previous time from the current time. Time distance is set back to 0 when ID goes to the next one.

I have tried a program, it works.

proc sort data=origin out=origin_sort;
	by ID Time;
run;

data distance;
	set origin_sort;
	retain distance previous;
	by ID;
	if first.ID=1 then
		do;
			distance=0;
			previous=time;
		end;
	else do;
			distance=Time-previous;
			previous=previous+distance;
		end;
run;

proc print;
run;

I obtain the output as I want.

However, I have to use two variables, and previous is exactly the same as Time.

Do you think this is a best way to do or could you suggest some way better?

Thank you for reading.

P/S: I cannot copy and paste table into this question so I have to use image. I do not know how to use table here. Could you please guide me?

[novinosrin · Accepted solution]

data origin;
	input ID Time;
	cards;
		12	3
		12	5
		12	18
		16	7
		16	25
		16	28
		16	44
	;
run;

data want;
set origin;
by id;
 dist=dif(time);
 if first.id then dist=0;
run;

[novinosrin]

or 

data want;
set origin;
by id;
 dist=ifn(first.id,0,dif(time));
run;

[trungdungtran]

Thank you so much for letting me know a new function in SAS.