Finding the Mode and Frequency of Mode for Series of Categorical Variables

[JackZ295]

Is there a way to find the mode and the frequency of the mode across a series of categorical variables ex. not just the mode for one variable, but the most frequent response among several variables?

Ex. Several items are scored as follows: 

1: No, strongly disagree

2: No, somewhat disagree

3: Neither agree nor disagree

4: Yes, somewhat agree

5: Yes, strongly agree

data sample; 
input id A1Q1 A2Q1 RFQ1 SE1Q1 SE2Q1 SE3Q1 SE4Q1 I1Q1 I2Q1 I3Q1 I4Q1; 
datalines;
1 2 1 1 3 3 4 2 5 3 2 
2 1 1 1 1 1 1 1 1 1 1
3 2 3 4 5 1 2 3 4 5 1 
4 1 2 3 4 5 5 4 3 2 1
5 1 1 1 1 1 1 1 1 1 1
;

As an example, how can I find the mode and the frequency of the mode of this data set across the variables 

A1Q1 A2Q1 RFQ1 SE1Q1 SE2Q1 SE3Q1 SE4Q1 I1Q1 I2Q1 I3Q1 I4Q1?

[Kurt_Bremser]

Do a transpose and freq:

data sample; 
input id A1Q1 A2Q1 RFQ1 SE1Q1 SE2Q1 SE3Q1 SE4Q1 I1Q1 I2Q1 I3Q1; 
datalines;
1 2 1 1 3 3 4 2 5 3 2 
2 1 1 1 1 1 1 1 1 1 1
3 2 3 4 5 1 2 3 4 5 1 
4 1 2 3 4 5 5 4 3 2 1
5 1 1 1 1 1 1 1 1 1 1
;

proc transpose data=sample out=trans;
by id;
run;

proc freq data=trans;
tables col1;
run;

I removed one variable from the input, as your datalines have only 11 columns.

[JackZ295]

Hi @Kurt_Bremser , thank you for your help. However, I actually have the find the mode and frequency of the mode for 50 sets of these (ex. 

A1Q1 A2Q1 RFQ1 SE1Q1 SE2Q1 SE3Q1 SE4Q1 I1Q1 I2Q1 I3Q1

A1Q2 A2Q2 RFQ2 SE1Q2 SE2Q2 SE3Q2 SE4Q2 I1Q2 I2Q2 I3Q2

A1Q3 A2Q3 RFQ3 SE1Q3 SE2Q3 SE3Q3 SE4Q3 I1Q3 I2Q3 I3Q3

.....

all the way to Q50.)

I just gave an abbreviated version as an example. I have to find a separate mode and frequency of the mode for each set of 11 variables. 

All of the variables are in the same data set. The data set is set up such that there is one row per participant. 

Any advice regarding this?

[Kurt_Bremser]

So you want to know the most often used answer for each column separately?

That can be done in one proc:

proc freq data=sample (drop=id);
tables _all_;
run;

[JackZ295]

Hi @Kurt_Bremser, thanks again for your help. I should be a little more clear in terms of what the data set looks like. It more or less looks like this: 

ID A1Q1 A2Q1 RFQ1 SE1Q1 SE2Q1 SE3Q1 SE4Q1 I1Q1 I2Q1 I3Q1 I4Q1  A1Q2 A2Q2 RFQ2 SE1Q2...

1 [Responses from likert scale are here]

2

3

4

5

6

7

8

9

10

I need to find the mode and frequency of the mode in each set of 11: 

A1Q1 A2Q1 RFQ1 SE1Q1 SE2Q1 SE3Q1 SE4Q1 I1Q1 I2Q1 I3Q1 I4Q1  (mode and frequency of mode for set 1)

A1Q2 A2Q2 RFQ2 SE1Q2 SE2Q2 SE3Q2 SE4Q2 I1Q2 I2Q2 I3Q2 I4Q2  (mode and frequency of mode for set 2) 

.....                  

                                                                                                                      (mode and frequency of mode for set 50)

Any advice?

I also need to find a way to output this data so that I can perform calculations using the frequency of the mode. 

[Kurt_Bremser]

Does that mean that, for the final frequency count, you treat each set of 11 variables as basically one column?

[JackZ295]

@Kurt_Bremser, thanks again for your help. I would be treating each set of 11 variables as one row.

[Kurt_Bremser]

Since SAS procedures are designed to work vertically, you would transpose your "rows" into vertical groups:

data sample; 
input id A1Q1 A2Q1 RFQ1 SE1Q1 SE2Q1 SE3Q1 SE4Q1 I1Q1 I2Q1 I3Q1; 
datalines;
1 2 1 1 3 3 4 2 5 3 2 
2 1 1 1 1 1 1 1 1 1 1
3 2 3 4 5 1 2 3 4 5 1 
4 1 2 3 4 5 5 4 3 2 1
5 1 1 1 1 1 1 1 1 1 1
;

proc transpose data=sample out=trans;
by id;
run;

data trans1;
set trans;
varset = input(scan(_name_,2,'Q'),best.);
run;

proc freq data=trans1 noprint;
tables varset*col1 /out=want;
run;

The crucial step here is the creation of the varset variable; if your name structure is as shown, using the "Q" as delimiter makes this very simple.

[JackZ295]

Hi @Kurt_Bremser thanks again for your help. Would you mind further explaining what this line of code does? 

varset = input(scan(_name_,2,'Q'),best.);

Thanks. 

[Kurt_Bremser]

Sorry for being late, but the weekend ...

---

@JackZ295 wrote:

Hi @Kurt_Bremser thanks again for your help. Would you mind further explaining what this line of code does? 

varset = input(scan(_name_,2,'Q'),best.);

Thanks. 

---

scan() splits out "words" from the first argument; the second argument is the "word" count, and the (optional) third argument contains a delimiter. Note my use of words in quotes, as you can use this in a lot of ways that don't relate to our usual concept of words in language.

So what this does is it takes everything out of the source after the first "Q", either up to the end of the source or to a possible second "Q".

Then I use input() to convert the string to a number.