Dynamically adapting the value of a macro variable using call symputx

[pkopersk]

Hello I am struggling with the function substr() and symputx().

* I am trying to generate this variable automatically;
%let suiviassinc=dsi_asti.suiviassincnew1807;



*this is my code;


%let annee=2018; 
%let mois=11; 

data _null_;  
	
	call symputx('a',substr("&annee",3,4));

        call symputx('suiviassinc',"dsi_asti.suiviassincnew&a&mois");
run;

Upon running the code I am getting the following error:

NOTE: Invalid third argument to function SUBSTR at line 397 column 22.

Can you please explain the issue here?

Thanks for your help

[novinosrin · Accepted solution]

I have no clue what your real objective is i.e in other words what you want to accomplish and why the macro

But if you want just help and only just to make your code work, here you go

* I am trying to generate this variable automatically;
%let suiviassinc=dsi_asti.suiviassincnew1807;



*this is my code;


%let annee=2018; 
%let mois=11; 

data _null_;  
	
	call symputx('a',substr("&annee",3,2));

        call symputx('suiviassinc',resolve("dsi_asti.suiviassincnew&a&mois"));
run;

%put &suiviassinc;

[PaigeMiller]

SUBSTR third argument should be the length of text you want to extract, which in this case seems it should be 2 and not 4.

In the future, please post the SASLOG when there are errors or warnings or notes that you don't understand.

[RW9]

The function substr() is of the form:

substr(<string>,<start position>,<number of characters to read>)

You are saying from the 3rd character, read 4 characters - which exceeds the length of the string.

So this:

call symputx('a',substr("&annee",3,4));

Should read:

call symputx('a',substr("&annee",3,2));

 To get the two characters from position 3 onwards, which is "18".

Also, you are overcomplicating your code, no need to create another macro variable, just do:

%let suiviassinc=dsi_asti.suiviassincnew1807;
%let annee=2018; 
%let mois=11; 

data _null_;  	
  call symputx('suiviassinc',cats("dsi_asti.suiviassincnew",substr("&annee.",3,4),"&mois."));
run;

 Please also, always put the decimal point after macro variables.

[Astounding]

Even once you resolve that error, there is an additional reason the code will not work.  You cannot create &A within a DATA step, and then use it within the same DATA step.  Basically, SAS has to determine what your statements are all about, before it has created &A.  You would be better off keeping all your code in macro language:

%let annee=2018;
%let mois=11;

%let a = %substr(&annee, 3, 2);
%let suiviassinc = dsi_asti.suiviassincnew&a&mois;

Even if you must use a DATA step for some other reason, you can emulate the %LET statement with:

data _null_;
call symputx('suiviassinc', "dsi_asti.suiviassincnew&a&mois");
run;