Data step how to rearrange variable order

[PaigeMiller]

Rarely is re-arranging the order of variables necessary. Why do you need to do this?

[purpleclothlady]

Hi Paige:

I am working on large datasets with lots of variables, some data sets need to open in data step such as : subject, date, order... 

thank you,

Purple

[purpleclothlady]

Hi All:

I wander if there is any other ways to rearrange var. order in Data step ?

• Methods:
• ATTRIB statement but we have to put length, format... . , which is not handy.

data attrib_method;
    attrib day month year date sales length=3;
    set sashelp.retail(obs=5);
run;

• If we use RETAIN before SET statement, will this sometimes accidentally change the variable values

  data retain_method;
      retain day month year date sales;
      set sashelp.retail;
  run;

  However, unless the sole purpose of a data step is to re-order variables, the use of RETAIN for this purpose can lead to unwanted results when the value of any ‘retained’ variable is carried over from one data step iteration to another.

Are there any other ways?

thanks all in advance.

purple

[Astounding]

"Carryover" of values is not an issue when you use a SET statement.  ALL variables from a SAS data set are automatically retained.  So adding a RETAIN does not change that feature, and does not change which variables are being retained.

[purpleclothlady]

Hi Astounding:
thanks for clarification. I will test it.

[Tom]

One simple way to insure that the dataset is defined as you want is to have a template or skeleton dataset that you can use to set the variables.

data want;
   set template(obs=0)  have;
run;

[purpleclothlady]

Hi Tom:
here is an example:
data cars;
set sashelp.cars;
run;

/*---WANT--- THE LAST 5 VARIABLES: ORIGIN, LENGTH, WHEELBASE,WEIGT ,MPG_HIGHWAY TO BE SHOWN AS THE FIRST 5 VARIABLES*/
data template;
input ORIGIN $ LENGTH WHEELBASE WEIGT MPG_HIGHWAY ;
datalines;
run;
data want;
set template(obs=0) cars;
run;
Question:
There are mixed char and numeric , I would need to specify that in input statement.
Is this the right way of creating template?

thank you

[Tom]

INPUT statement is for reading in values, not for DEFINING the variables.

I would use LENGTH or ATTRIB to define the variables.

data template ;
  length origin $6 length wheelbase weight mpg_highway 8;
  label
    length = 'Length (IN)'
    wheelbase = 'Wheelbase (IN)'
    weight = 'Weight (LBS)'
    mpg_highway = 'MPG (Highway)'
  ;
  stop;
  call missing(of _all_);
run;

And yes if your template defines the variable as numeric and the dataset you are trying to modify has it as character that is an ERROR that you would want the code to detect.

Another way to impact the order is using the KEEP= (or DROP=) dataset option.

data want;
  set
   sashelp.cars(keep=origin)
   sashelp.cars(keep=length)
   sashelp.cars(keep=wheelbase)
   sashelp.cars(keep=weight)
   sashelp.cars(keep=mpg_highway)
   sashelp.cars
 ;
run;

[andreas_lds · Accepted solution]

another method:

data want;
   format Origin Length Wheelbase Weight mpg_highway;
   set sashelp.cars;
run;

[tarheel13]

I like format or retain best.

[purpleclothlady]

Hi all:

Thanks all for your help. 

They all work in Data Step but depending on your preference .

Using 1. Retain(with caution), 2. Format, 3. Adding a Template dataset , 4. Attrib, 5. Keep/drop (this one will create more obs than original)