hi ... so this is not a direct answer to the question, but just another way to look at the weight change data
if you want a display of logs of weight change, you know that you'll have to 'throw away' the zero and negative numbers
so, here's a non-GTL way of looking at the same data that looks slightly similar to your GTL plot
weight change is always 0 or positive
gain is blue, lose is red
this gives a 'log look' at both weight gain and weight loss
[pre]
*
rearranging data ... +/0 in one group, - in another
two groups
;
data bwt;
set sashelp.bweight (keep=visit m_wtgain);
select;
when (m_wtgain ge 0) do; group=1; lvisit=3*visit; end;
when (m_wtgain lt 0) do; group=2; lvisit=3*visit+1; end;
end;
lm_wtgain = abs(m_wtgain);
run;
* some SAS/Graph options;
goptions reset=all ftext="calibri" htext=1
device=gif xpixels=1000 ypixels=1000 gsfname=gout ;
axis1 label=(a=90 "MOM'S WEIGHT CHANGE (POUNDS)");
axis2 label=(a=90 "MOM'S WEIGHT CHANGE (POUNDS, LOG SCALE)")
logbase=10;
axis3 offset=(5,5)pct minor=none order=-0 to 10 by 1
major=(c=white) label=('VISIT')
value=(
tick=1 c=blue j=c "0" j=c "GAIN" tick=2 c=red j=c "0" j=c "LOSE" tick=3 ""
tick=4 c=blue j=c "1" j=c "GAIN" tick=5 c=red j=c "1" j=c "LOSE" tick=6 ""
tick=7 c=blue j=c "2" j=c "GAIN" tick=8 c=red j=c "2" j=c "LOSE" tick=9 ""
tick=10 c=blue j=c "3" j=c "GAIN" tick=11 c=red j=c "3" j=c "LOSE" tick=12 "");
symbol1 v=dot h=1 c=blue;
symbol2 v=dot h=1 c=red;
* for white space around the chart;
title1 ls=1;
title2 ls=1 a=90;
title3 ls=1 a=-90;
footnote1 ls=1;
*
two plots ... one regular, one log (base 10)
not printed ... used later in GREPLAY
;
filename gout dummy;
proc gplot data=bwt gout=plots;
plot lm_wtgain*lvisit=group / vaxis=axis1 haxis=axis3 nolegend name='one';
run;
plot lm_wtgain*lvisit=group / vaxis=axis2 haxis=axis3 nolegend name='two';
where lm_wtgain ne 0;
run;
quit;
goptions xpixels=2000;
* destination for output;
filename gout "z:\bwt.gif";
proc greplay igout=plots nofs;
tc sashelp.templt;
template h2;
tplay 1:one 2:two;
quit;
* chance to use KILL in SAS;
proc catalog c=plots kill;
run;
quit;
[/pre]