Overlaying a panels with line plots

[Melk]

I have a vertical bar plot of means by visit number paneled by group.

Since I only have a few patients in my sample, I would like to overlay this plot with individual line plots. Is there an easy way to do this?

[PeterClemmensen]

Use the SERIES Statement to plot your individual IDs and use the VBARPARM instead of VBAR, since SERIES and VBAR cannot be overlayed. 

Also check out Plot Type Compatibility for a nice summary of what plot types can be overlayed in PROC SGPLOT

[PeterClemmensen]

Be aware though, that with VBARPARM, you have to calculate the mean values beforehand. 

Also, provide some sample of your data to get a code answer 🙂

[Melk]

Sure and thanks!

Sample data:

ID     Visit     Group     Y

1        1           0         20

2        1           0         24

3        1           1         33

4        1           1         15

5        1           0         26

6        1           1         25

1        2           0         16

2        2           0         12

3        2           1         53

4        2           1         23

5        2           0         10

6        2           1         29

[PeterClemmensen · Accepted solution]

If I understand you correctly, then do something like this

data have;
input ID$ Visit Group Y;
datalines;
1 1 0 20
2 1 0 24
3 1 1 33
4 1 1 15
5 1 0 26
6 1 1 25
1 2 0 16
2 2 0 12
3 2 1 53
4 2 1 23
5 2 0 10
6 2 1 29
;

proc sql;
	create table help as
	select *
	      ,mean(Y) as VisitMean
	from have
	group by Group, Visit
	order by Group, Visit, ID;
quit;

title "Panel Overlayed With Line Plots";
proc sgpanel data=help;
	panelby Group;
	vbarparm category=visit response=VisitMean;
	series x=Visit y=y / group=ID markers markerattrs=(symbol=circlefilled);
	rowaxis display=(nolabel) grid;
	colaxis display=(nolabel);
run;

[Melk]

worked beautifully, thank you!