Pyrite | Level 9

## Adding percentiles as references lines

Hi,

Is there any way to add percentiles ( maybe only the first, second and third percentiles) as vertical reference lines on the density normal plot?

thanks

1 ACCEPTED SOLUTION

Accepted Solutions
SAS Super FREQ

## Re: Adding percentiles as references lines

Here's one way to do it:

``````proc means data=sashelp.heart P25 P50 P75;
var cholesterol;
ods output summary=pctls;
run;

data merged;
set sashelp.heart pctls;
run;

proc sgplot data=merged;
density cholesterol;
refline Cholesterol_P25 / axis=x legendlabel="25th" lineattrs=(color=blue thickness=3) name="p25";
refline Cholesterol_P50 / axis=x legendlabel="50th" lineattrs=(color=red thickness=3) name="p50";
refline Cholesterol_P75 / axis=x legendlabel="75th" lineattrs=(color=green thickness=3) name="p75";
keylegend "p25" "p50" "p75" / title="Percentiles";
run;``````

Hope this helps!

Dan

2 REPLIES 2
SAS Super FREQ

## Re: Adding percentiles as references lines

Here's one way to do it:

``````proc means data=sashelp.heart P25 P50 P75;
var cholesterol;
ods output summary=pctls;
run;

data merged;
set sashelp.heart pctls;
run;

proc sgplot data=merged;
density cholesterol;
refline Cholesterol_P25 / axis=x legendlabel="25th" lineattrs=(color=blue thickness=3) name="p25";
refline Cholesterol_P50 / axis=x legendlabel="50th" lineattrs=(color=red thickness=3) name="p50";
refline Cholesterol_P75 / axis=x legendlabel="75th" lineattrs=(color=green thickness=3) name="p75";
keylegend "p25" "p50" "p75" / title="Percentiles";
run;``````

Hope this helps!

Dan

Pyrite | Level 9

## Re: Adding percentiles as references lines

Yes, it helped a lot. Thank you SO much!

Discussion stats
• 2 replies
• 680 views
• 1 like
• 2 in conversation